@@ +Mail and BB system using MySQL
@@ for PennMUSH 1.8.1p9 and higher
@@
@@ ** NOW REQUIRES 1.8.1p9 OR HIGHER **
@@
@@ August 16 2005
@@ Written by Talvo@ElendorMUSH / Mike@M*U*S*H
@@
@@ COPYRIGHT AND SUPPORT:
@@ This code is free for anyone to use. However:
@@  1) if it breaks (itself or other stuff), don't blame me.
@@  2) don't take credit for my code.
@@
@@ For any support stuff, please feel free to email me. My current address is
@@ mike@keyboardzombie.com . I'll do my best to fix any bugs you might find as quickly as possible,
@@ and if you have problems installing or setting up the system, I'll try and help with those, too,
@@ but may not always have the time to do so. If you find a bug and fix it (or add a new feature
@@ or anything), please feel free to send me it, and I'll include it in the file (you will be
@@ fully credited for the code). Feature requests (without code) are also welcomed, though again may
@@ not make it in, either due to lack of time or because it's not compatible with the way the system
@@ works.
@@
@@ And now that's out the way, a short description of the code: This is a +Mail and Bulletin Board
@@ system for PennMUSH 1.8.1. It stores the messages off the MUSH, in a MySQL database.
@@ It also has an accompanying POP3 server, which means you can download your mail from the MUSH into
@@ a mail client like Outlook Express/Thunderbird, etc, or even set up web-based systems like
@@ SquirrelMail to check it. SMTP (for sending mail) and NNTP (for downloading BB posts) may be
@@ added at some point in the future; if you'd be interested in having them, let me know.
@@
@@ All the commands will be made "global", via @command/add and @hook, with the exception of
@@   '-' (short for +write) and '--' (short for +send), b/c it's not possible with softcode.
@@
@@ 4 MySQL tables are used (named inbox, bbinbox, undo and mail), and are created by the code.
@@ You can give the tables a prefix - the default is 'mm_' - by setting the appropriate config
@@ version. See below for that. Tested on MySQL version 4.0.24
@@
@@ The latest version of this code (and help-files) are available from www.keyboardzombie.com
@@
@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@
@@ INSTALLATION INSTRUCTIONS:
@@ I would recommend a function_invocation_limit of at least 3500 ideally (higher is no problem).
@@ Setting this should be no problem - Keran's weather system (which has been around several
@@ years) asks for 12,500, and M*U*S*H's is set to 25,000. Uncomment out this line to set
@@ your function_invocation_limit to 3500 if it's currently set lower:
@@
@@ @switch [config(function_invocation_limit)]=<3500,@config/set function_invocation_limit=3500
@@
@@ It's suggested you create a Wizard character specifically for uploading this code. Even if
@@ you don't make a special char for it though (beware it overwriting attrs on yourself if you dont!)
@@ it still needs to be run by a Wizard. He must also be set NO_PAY, or things will fail.
@@
@@ There are various +MAIL options. These can all be set in-game, at any time, via the command
@@ +mail/config. You can find them below and change them if you wish, though (probably best, as
@@ a few are used during the setup, particularly the db_prefix option).
@@
@@ If you're upgrading, comment out the lines below which create the objects you already have.
@@
@@ You will need to set safer_ufun to "no" in your mush.cnf file in order to use this code.
@@ (If you don't want to do that for some reason, you can probably get away with doing something
@@ like @SET %VB/**=PUBLIC at the end, instead.)
@@
@@ (Keep reading 'til it says not to; there's some code among these comments because you
@@ need to do special things with it before/after the installation.:)
@@
@@ You may also want to alter the way FUN.ALTS works, to tie into your own ALT system
@@ (alternate character). It allows players to read their alts mail, via the '@<alt>' syntax.
@@ PLEASE NOTE that even if you don't have an alt system, you should still set the default
@@ value. Do -not- delete this totally!
@@
@@ The default assumes players alts are stored on them in an attr named ALTS, which contains objids, not dbrefs.
@@ FUN.ALTS - return all of %0's alts, including %0 himself (objids, not dbrefs). The default simply returns %0.
&FUN.ALTS me=setunion(get(%0/ALTS),%0)

@@ This @lock controls who can read all sent mail via +READ/SENT, +skim non-alts, etc.
@@ Suggested: wiz/roy, perhaps see_all too.
@@ If you're worried about security/privacy, lock this to #false instead, so only 
@@ a player (and his/her alts) can read his mail, and staff can't.
@@ @lock/user:see_all me=#false
@@ @lock/user:see_all me=FLAG^WIZARD|FLAG^ROYALTY
@lock/user:see_all me=FLAG^WIZARD|FLAG^ROYALTY|POWER^SEE_ALL

@@ Who can use the sendmail() function (%vb/fun.sendmail)? Note that anyone using this function
@@ can send mail as /any player/ on the game - it's intended for staff-owned automated/coded systems,
@@ not for players.
@@ @lock/user:sendmail me=FLAG^WIZARD&(TYPE^THING|TYPE^EXIT|TYPE^ROOM)
@lock/user:sendmail me=FLAG^WIZARD

@@ Do you want to set yourself QUIET during the installation? 1 to hide the spam, 0 to see it.
&quiet`during me=0

@@ STUFF FOR GOD (#1) TO DO (to be run just after you upload this code):
@@ Create a 'mailban' flag, which is set on players (via +mail/ban) to stop them sending mail.
@@ @flag/add MAILBAN=,player,wizard mdark,wizard

@@ Add attributes used by the mail system (you'll need to put these into an @startup on
@@ #1, or another low-dbref object, so that they run straight away when the MUSH restarts):
@@ @attr/access/retroactive mailsignature=no_command prefixmatch
@@ @attr/access/retroactive mailfailure=no_command prefixmatch
@@ @attr/access/retroactive bbignore=no_command mortal_dark wizard

@@ Set up the global SENDMAIL() function. (This also needs adding into an @startup, like
@@ the @attrs above do. You may wish to manually put the dbref for %vb in place of '[get(*MailBot/VB)]')
@@ @function/preserve sendmail=[get(*MailBot/VB)],FUN.SENDMAIL,4,5

@@ For the POP3/NNTP servers.. You may also wish to change the MailBot character's
@@ password (the default is BotMail), but make sure you record the new one for the servers.
@@ @newpassword *MailBot=YourNewPasswordHere!

@@ Make all the commands global (only God can @command/add). 
@@ This should be in God's @startup somewhere. It /does not work/ pasted straight in from your client.
@@ @assert cand(numversion(),gte(numversion(),1008001006)); @dolist bbcreate bbdelete bbinfo bblist bbscan bbignore bbcatchup bbleave address cc reply include includes subject write undo send proof draft edit unread read skim undelete delete deleted expunge clear toss erase outbox unmail={@command/add +## ; @hook/override +##=[get(*MailBot/VA)],cmd.##} ; @dolist bbadmin bbauthor bbdesc bblock bbheader bbtimeout forward mail mgroup={@command/add/eqsplit +## ; @hook/override +##=[get(*MailBot/VA)],cmd.##}


@@ If you're trying to install this on a pre-1.8.1p9 game, you brought this flashing ANSI on yourself. :P
think if(cand(numversion(),gte(numversion(),1008001009)),Beginning installation...,ansi(hgfu,THIS SYSTEM REQUIRES AT LEAST PENNMUSH 1.8.1p9 IN ORDER TO WORK CORRECTLY. YOU APPEAR TO BE USING AN EARLIER VERSION. IT'S HIGHLY RECOMMENDED THAT YOU UPGRADE YOUR COPY OF PENNMUSH BEFORE YOU INSTALL OR USE THIS CODE.))


@@ When you're happy with how those values are set, simply upload the code using TF's /quote
@@ command, or copy and paste it all in (and then run the 'Stuff for God' code afterwards). You
@@ can stop reading, now, unless you want to manually change the config options below, or you're
@@ upgrading and need to comment out the object-creation lines below :)
@@
@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@
@@ CODE BEGINS
@@
@set me=quiet`before:[hasflag(%!,quiet)]
@set me=[if(v(quiet`during),QUIET,!QUIET)]
@@ Create the objects. Comment these lines out if you're upgrading.
@SET ME=VA:[create(+MAIL Commands)]
@SET ME=VB:[create(+MAIL Functions)]
@SET ME=VC:[create(+MAIL Messages)]
@SET ME=VD:[create(+MAIL Database)]
@SET ME=VZ:[pcreate(MailBot,BotMail)]

@@ If you're upgrading, you'll want to wipe the old objects and start fresh (don't wipe %vd!):
@@ @dolist %VA %VB %VC %VZ=@wipe ##

@@ The Wiz flag can't be avoided; we need it for objeval()
@set %vb=WIZARD
@power %va=SQL_OK CAN_NSPEMIT NO_PAY PEMIT_ALL SEE_ALL
@power %vb=NO_PAY
@dolist %va %vb %vc %vd=@lock/examine ##==%va|=%vb|=%vc ; @set ##=VISUAL
@lock/interact %vz=$me
@set %vz=!ANSI !COLOR QUIET NO_WARN
@power %vz=NO_PAY HIDE IDLE QUEUE CAN_NSPEMIT

@set %va=LOUD
@set %vb=LOUD


@dolist setdiff(lattr(me/V?),VP)=@cpattr me/##=%va,%vb,%vc,%vd,%vz

@mvattr me/fun.alts=%vb
@mvattr me/fun.isalt=%vb
@lock/user:see_all %vb=[lock(me/see_all)]
@lock/user:see_all me
@lock/user:sendmail %vb=[lock(me/sendmail)]
@lock/user:sendmail me

@@ Much, much easier. There will be a function for sending mail from objects (wiz-only, mind you)
@lock/use %va=TYPE^PLAYER

@desc %va=ufun(%vb/describe)
@desc %vb=[repeat(=,78)]%r[iter(lattr(me/info`*),rest(%i0,`) - [u(%i0)],,%r)]%r[repeat(-,78)]%rFor more info, see HELP MAIL VERSION and HELP MAIL CREDITS%r[repeat(=,78)]
&INFO %vb=Info about the system, author, etc, are under here. Ex %!/info** for more.
&INFO`AUTHOR %vb=Talvo@ElendorMUSH
&INFO`CREDITS %vb=Code by Talvo@ElendorMUSH. Based on ElendorMUSH's +mail system, which was written by Lukthil@ElendorMUSH. Help and inspiration from Fraibert@ElendorMUSH and Benigo@ElendorMUSH. Cheetah@M*U*S*H wrote the new regexp used in FUN.PARSEARGS, and I will love him forever for it ;) Walker@M*U*S*H helped a hell of a lot with the regexp'ing in +edit/regexp\[all\]\[i\], and greatly improved its power. See HELP MAIL CHANGES for full change-list with credits.
&INFO`DESC %vb=An integrated +MAIL and Bulletin Board system for PennMUSH 1.8.1 and higher.
&INFO`EMAIL %vb=talvo@talvo.com
&INFO`FROM %vb=http://www.talvo.com/
&INFO`NAME %vb=Talvo's +Mail and BB System
&INFO`VERSION %vb=2.3

@set %vb/info**=visual

@@ Here for safe keeping:
@@ (?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)?

@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ MUSH commands...
@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ Commands:                                              Done
@@
@@ +mail [@<alt>] [<bb>]  . . . . . . . . . . . . . . . .  X-H
@@ +mail [@<alt>] <addr>=<subject>  . . . . . . . . . . .  X-H
@@ +reply [@<alt>] [<bb>] <range> . . . . . . . . . . . .  X-H
@@ +forward [@<alt>] [<bb>] <range>=<addr>  . . . . . . .  X-H
@@ +include [@<alt>] [<bb>] <range> . . . . . . . . . . .  X-H
@@ +includes  . . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +include/remove [<ids>]  . . . . . . . . . . . . . . .  X-H
@@ +subject <new> . . . . . . . . . . . . . . . . . . . .  X-H
@@ +address <addr>  . . . . . . . . . . . . . . . . . . .  X-H
@@ +cc <addr> . . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +cc/remove <addr>  . . . . . . . . . . . . . . . . . .  X-H
@@ -<msg> . . . . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +write[/nospace][/noeval] <msg>  . . . . . . . . . . .  X-H
@@ +undo  . . . . . . . . . . . . . . . . . . . . . . . .  X-H
@@ -- . . . . . . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +send[/nosig][/loud] . . . . . . . . . . . . . . . . .  X-H
@@ +proof[/examine] . . . . . . . . . . . . . . . . . . .  X-H
@@ +draft . . . . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +read[/examine] [@<alt>] [<bb>] [<range>]  . . . . . .  X-H
@@ +read/sent[/examine] [@<alt>] <id> . . . . . . . . . .  X-H
@@ +read/mark [@<alt>] [<bb> [<range>]  . . . . . . . . .  X-H
@@ +bbread <bb>/<range> . . . . . . . . . . . . . . . . .  X-H
@@ +skim [@<alt>] [<bb>] [<range>]  . . . . . . . . . . .  X-H
@@ +delete[/force] [<bb>] <range>   . . . . . . . . . . .  X-H
@@ +deleted . . . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +undelete <range>  . . . . . . . . . . . . . . . . . .  X-H
@@ +unread <range>  . . . . . . . . . . . . . . . . . . .  X-H
@@ +clear . . . . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +edit <old>/<new>  . . . . . . . . . . . . . . . . . .  X-H
@@ +edit/delim <delim> <old><delim><new>  . . . . . . . .  X-H
@@ +edit/regexp[all][i] <delim> <old><delim><new> . . . .  X-H
@@ +toss  . . . . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +erase[/all] . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +outbox[/id] [@<alt>]  . . . . . . . . . . . . . . . .  X-H
@@ +unmail <id> . . . . . . . . . . . . . . . . . . . . .  X-H

@@ +mail/ban <player> . . . . . . . . . . . . . . . . . .  X-H
@@ +mail/unban <player> . . . . . . . . . . . . . . . . .  X-H
@@ +mail/banned . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +mail/config [<option>[=<value>]]  . . . . . . . . . .  X-H
@@ +mail/purge  . . . . . . . . . . . . . . . . . . . . .  X-H

@@ +bbscan [@<alt>] . . . . . . . . . . . . . . . . . . .  X-H
@@ +bblist[/all] [@<alt>] . . . . . . . . . . . . . . . .  X-H
@@ +bbinfo <bb> . . . . . . . . . . . . . . . . . . . . .  X-H
@@ +bbcreate <bb> . . . . . . . . . . . . . . . . . . . .  X-H
@@ +bbdelete <bb> . . . . . . . . . . . . . . . . . . . .  X-H
@@ +bbdesc <bb>=<desc>  . . . . . . . . . . . . . . . . .  X-H
@@ +bblock[/write|/read|/notify] <bb>=<lock>  . . . . . .  X-H
@@ +bbtimeout <bb>=<timeout>  . . . . . . . . . . . . . .  X-H
@@ +bbadmin[/noeval] <bb>=<ufun>  . . . . . . . . . . . .  X-H
@@ +bbignore <bb> . . . . . . . . . . . . . . . . . . . .  X-H
@@ +bbcatchup <bb> [<range>]  . . . . . . . . . . . . . .  X-H
@@ +bbread <bb>/<range> . . . . . . . . . . . . . . . . .  X-H
@@ +bbheader <bb>=<header>  . . . . . . . . . . . . . . .  X-H
@@ +bbauthor <bb>=<str> . . . . . . . . . . . . . . . . .  X-

@@ +mgroup[/list] [<group>] . . . . . . . . . . . . . . .  X-H
@@ +mgroup/ex <group> . . . . . . . . . . . . . . . . . .  X-H
@@ +mgroup/add <group>=<list> . . . . . . . . . . . . . .  X-H
@@ +mgroup/remove <group> . . . . . . . . . . . . . . . .  X-H

@@ USED IN MySQL:
@@   TABLE: 'mail'
@@     COL: id (mail ID)
@@     COL: who (mail author; objid format)
@@     COL: date (date sent; secs() format)
@@     COL: subject (msg subject)
@@     COL: recip (recipients in objid and BB format)
@@     COL: body (message body)
@@     COL: sent (has it been sent(1) or is it being written(0))
@@     COL: sig (mail signature)
@@     COL: forwards (+forward/included message ids, if any, in format "|id1|id2|" -- none is "||")
@@   TABLE: 'inbox'
@@     COL: id (mail ID)
@@     COL: who (whose inbox it's in; objid)
@@     COL: status (the status of that message in that inbox - n, r or d)
@@   TABLE: 'undo'
@@     COL: who (author objid)
@@     COL: true (is there something to undo?)
@@     COL: data (the old message)
@@   TABLE: 'bbinbox'
@@     COL: id (mail ID)
@@     COL: bbcount (bb id number)
@@     COL: readers (list of objids of who's read it, in "|objid|objid|" format -- none is "||")

@@ Some quick setups for attribute trees
&config %vb=Config options are below this branch, and may be altered with +MAIL/CONFIG

@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ CONFIG OPTIONS
@@ You may want to change some of these.
@@ Config format: config`option = description
@@                config`option`type = string, bool, int, etc
@@                config`option`value = current setting
@@                config`option`onchange = ufun to be run when value changes (%0 is the new value)
@@ Config options are NOT evaluated when called unless specifically stated.

@@ Admins: Who is an admin in the mail system
@lock/user:isadmin %vb=FLAG^WIZARD|FLAG^ROYALTY

&config`locale %vb=Language/locale: In case anyone ever translates this stuff into another language.
&config`locale`type %vb=string
&config`locale`value %vb=en
&config`locale`onchange %vb=set(%vb,msg:[edit(get(%vb/msgx),%%LANG%%,%0)])

&config`mudname %vb=The name of the MUSH, where the mail sys uses it.
&config`mudname`type %vb=string
&config`mudname`value %vb=PennMUSH
&config`mudname`onchange %vb=nspemit(%vb,SELF-TRIGGER-SETUP)

&config`accents %vb=Show accents in player names?
&config`accents`type %vb=bool
&config`accents`value %vb=1
&config`accents`onchange %vb=set(%vb,fun.propername:[get(%vb/fun.propername-accents%0)])[set(%vb,fun.propername-enactor:[get(%vb/fun.propername-enactor-accents%0)])]

&config`purgedname %vb=What string should we use to signify a purged player?
&config`purgedname`type %vb=string
&config`purgedname`value %vb=<Purged>

&config`tag %vb=Tag for mail commands. Should end in a space (\[+MAIL\]%b, for example.)
&config`tag`type %vb=string
@fo me=&config`tag`value %vb=[lit(\[+MAIL\]%b)]

&config`sql_wildcard %vb=What is the wildcard equiv. to Penn's * in your SQL?
&config`sql_wildcard`type %vb=string
&config`sql_wildcard`value %vb=%

&config`default_subject %vb=If someone starts a mail with no subject, what default do we use?
&config`default_subject`type %vb=string
&config`default_subject`value %vb=<No Subject>

&config`guests %vb=Can Guests send mail?
&config`guests`type %vb=bool
&config`guests`value %vb=0

&config`bbformat %vb=How do we display BB names in address lists? %%0 is the BB's name. This is evaluated.
&config`bbformat`type %vb=string
&config`bbformat`value %vb=(%0)

&config`max_includes %vb=How many messages can be +forward/+included inside a single +mail?
&config`max_includes`type %vb=int
&config`max_includes`value %vb=5

&config`max_reads %vb=How many messages can be read at once? Don't go too high, unless you can handle a high call_limit and invoc_limit
&config`max_reads`type %vb=int
&config`max_reads`value %vb=10

&config`bb_header %vb=Default header for new BBs. %%0 is the BB name. Note: This is eval'ed when the BB is created, /and/ when the header is needed.
&config`bb_header`type %vb=string
&config`bb_header`value %vb=center\(%%b%0%%b,78,=)

&config`bb_timeout %vb=How long (in seconds) after a message is posted on a BB will it expire? Use 86400 is 1 day, and 604800 is one week.
&config`bb_timeout`type %vb=time
&config`bb_timeout`value %vb=604800

&config`purge_time %vb=How long ago must a message have been written to no longer be "important", so we can purge it? This is in seconds. Default is 2592000, 30 days.
&config`purge_time`type %vb=time
&config`purge_time`value %vb=2592000

&config`connect_mail %vb=Should the results of '+mail' be shown to players on connect?
&config`connect_mail`type %vb=bool
&config`connect_mail`value %vb=1

&config`connect_bb %vb=Should the results of '+bbscan' be shown to players on connect?
&config`connect_bb`type %vb=bool
&config`connect_bb`value %vb=0

&config`db_prefix %vb=A string prefixed to the name of the SQL tables used. The default is 'mm_'.
&config`db_prefix`type %vb=string
&config`db_prefix`value %vb=mm_
&config`db_prefix`onchange %vb=set(%!,vp:[sqlescape(%0)])[iter(%va %vc %vd,set(%i0,VP:%vp))]
@set %vb=VP:[sqlescape(get(%vb/config`db_prefix`value))]
@cpattr %vb/VP=%va,%vc,%vd,me

@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ LANGUAGE CATALOGUE (English)

&en %vc=English

&en`unmail-readby %vc=WARNING! The following players have already read your message: [itemize(%0)]
&en`unmail-taken %vc=Player %0 just took message #%1 (entitled: %2) away from you!
&en`unmail-done %vc=Message ID #%0 recalled. Type +PROOF to see it, or +TOSS to destroy it.
&en`unmail-bad %vc=Either there is no sent message with that ID, or you did not write it. Type +OUTBOX to see a list of messages you sent.
&en`unmail-already-writing %vc=You cannot +unmail while you're writing a message. Finish your current mail (or +TOSS it) and then +unmail.

&en`outbox-num %vc=There [ufun(%vb/fun.plural,%0,is 1 sent message,are %0 sent messages)] in the database.
&en`outbox-none %vc=There are no sent messages from you in the database.
&en`erase %vc=You erase your message content. Type +UNDO to undo the change.
&en`erase-all %vc=You erase your message content, subject, and +includes. Type +UNDO to put the content back.
&en`toss %vc=You throw your message away completely.
&en`clear %vc=Messages deleted.
&en`delete-new %vc=You are trying to delete at least one message which you have not read. You must read it first, or use +DELETE/FORCE to mark it for deletion without reading it.
&en`marked-as-del %vc=Messages marked for deletion: %0

@@ +mail checking command.
&en`player-check %vc=name(%0) has %1 [ufun(%vb/fun.plural,%1,message)] (%2 new, %4 marked for deletion).
&en`player-same-check %vc=You have %1 [ufun(%vb/fun.plural,%1,message)] (%2 new, %4 marked for deletion).
&en`board-check %vc=Board %0 has %1 [ufun(%vb/fun.plural,%1,message)] posted to it.

&en`no-such-player %vc=No such player '%0'.
&en`not-an-alt %vc=name(%0) is not your alt.

&en`no-such-bb %vc=There is no BB called '%0'.
&en`cant-read-bb %vc=You don't have permission to read the '%0' BB.

&en`already-writing %vc=You're already writing a message. Type +PROOF to see it.
&en`not-writing %vc=You are not currently writing a message.
&en`no-guest-mail %vc=Guest characters are not allowed to send mail.
&en`banned-from-mailing %vc=You are currently banned from sending +mail. Please contact the admins if you have any questions.

&en`no-good-players %vc=I couldn't find any of those people.
&en`these-players-bad %vc=I couldn't find any of these people: %0
&en`fail-locks-all %vc=You don't have permission to mail any of those people: [itemize(%0)]
&en`fail-locks-some %vc=You don't have permission to mail these people: [itemize(%0)]
&en`new-msg %vc=You start a new message (#%0).

&en`no-messages-you %vc=You have no messages.
&en`no-messages-player %vc=There are no messages in that player's inbox.
&en`no-messages-bb %vc=There are no messages posted on that BB.

&en`new-mail %vc=You have new mail from %1 (#%2).
&en`new-mail-nospoof %vc=You have new mail from %1(%0) (#%2).
&en`sent %vc=Message sent (#%0).

&en`no-good-replyers %vc=None of the original recipients of that message could be found to reply to.
&en`reply-to-one %vc=You can only reply to one message at a time. That range matches %0 messages.
&en`reply-msg %vc=You begin a reply to message %1 (#%0). 

&en`bad-range-date %vc=Invalid date range '%0'. Should be DATE=12345, DATE=<12345 or DATE=>12345.
&en`bad-status %vc=Invalid status '%0'. Should be R, N or D.
&en`bad-range-spec %vc=Unknown range specifier '%0'. See HELP MAIL RANGES.

&en`too-many-includes %vc=You cannot forward/include more than %0 [ufun(%vb/fun.plural,%0,message)] in a single +mail.
&en`attach %vc=You attach %0 [ufun(%vb/fun.plural,%0,message)] to your +mail.
&en`no-such-include %vc=There are no messages included in your mail with any of those IDs. Type +INCLUDES for a list, or +PROOF to see your mail.
&en`include-removed %vc=The following message IDs are removed from your mail: [itemize(%0)]
&en`forward-subject %vc=<fwd> %0 [ufun(%vb/fun.plural,%0,message)]: %1
&en`forward-msg %vc=You start a new message, forwarding %1 [ufun(%vb/fun.plural,%1,message)] (#%0).
&en`these-includes %vc=The following message IDs are included with your mail: [itemize(%0)]
&en`no-includes %vc=There are no messages included with your current +mail.

&en`subject-updated %vc=Subject changed.

&en`address-changed %vc=Address changed to: [itemize(%0)]
&en`cc-remove-all %vc=You can't remove everyone!
&en`cc-remove-who %vc=None of those players are recipients of your current +mail anyway!

&en`write %vc=You continue writing.

&en`undo %vc=You undo your last changes. Type +PROOF to see your message, or +UNDO to revert back to the message before this undo.

&en`mailfailure %vc=Mail failure message from %0: %1

&en`none-in-range %vc=There are no messages in that range.

&en`purged %vc=Messages purged.

&en`unknown-mail-switch %vc=Unknown switch for +MAIL command. Valid switches are /BAN, /UNBAN, /BANNED, /CONFIG, /PURGE and /VERSION.

&en`banned %vc=The following players are banned from sending mail: %0
&en`none-banned %vc=There are no mail-banned players.

&en`ban-already-banned %vc=That player is already banned from sending +mail! Use +MAIL/UNBAN <player> to unban someone.
&en`ban-banned %vc=You have just been banned from sending +mail. Please contact an admin if you have any questions regarding this ban.
&en`ban-you-banned %vc=You ban %0(%1) from sending mail.

&en`bbscan %vc=The following BBs have unread messages:
&en`bbscan-nonew %vc=There are no unread posts on any BBs you can read.
&en`bbscan-noread %vc=There are no BBs you can read.

&en`bblist-some %vc=Bulletin Boards which you can read:
&en`bb-noread %vc=There are no BBs which you can read.
&en`bblist-all %vc=Bulletin Boards on [ufun(%vb/config`mudname`value)]:

&en`bblock-set %vc='%0' lock for BB '%1' set to: %2
&en`bblock-bad-switch %vc=Invalid switch. Must be one of /WRITE, /READ or /NOTIFY.
&en`bbdelete %vc=You delete the '%0' BB.
&en`new-bb %vc=BB '%0' created. See HELP BB SETUP for how to set it up.
&en`bbcreate-existing %vc=There's already a BB with that name!
&en`invalid-bb-name %vc=That is not a valid BB name.
&en`permission-denied %vc=Permission denied.

&en`mgroup-none %vc=There are no Mailgroups on the game.
&en`mgroup-list-all %vc=The following Mailgroups exist on the game:%r%0
&en`mgroup-list %vc=The following players/BBs are in the '%0' Mailgroup: %1
&en`mgroup-badswitch %vc=Invalid switch. Must be one of /LIST, /EX, /ADD or /REMOVE.
&en`no-such-mg %vc=There is no Mailgroup with that name.
&en`mgroup-ex %vc=Definition of '%0' Mailgroup:%r%1
&en`mgroup-removed %vc=Mailgroup '%0' removed.
&en`mgroup-added %vc=Mailgroup '%0' added successfully.
&en`not-valid-mg %vc=That is not a valid name for a Mailgroup.
&en`already-a-mg %vc=There's already a Mailgroup with that name!

&en`too-many-reads %vc=You can only read %0 [ufun(%vb/fun.plural,%0,message)] at once.
&en`no-such-id %vc=There is no message with that ID.
&en`cant-read-sent %vc=You cannot read that message, as you were not the author or a recipient.
&en`read-sent-unsent %vc=That message hasn't been sent yet. Be patient!
&en`read-which %vc=Which message do you want to read?

&en`marked-as-new %vc=Messages marked as new: %0
&en`new-bb-posting %vc=New posting on %1 by %0 (#%2).
&en`forward-which %vc=Which message do you want to forward?
&en`reply-to-which %vc=Which message do you want to reply to?
&en`board-check %vc=Board %0 has %1 [ufun(%vb/fun.plural,%1,message)] posted to it (%2 unread).
&en`ban-unbanned %vc=You are no longer banned from sending +mail.
&en`ban-you-unban %vc=You unban %0(%1) - [subj(%1)] can now send +mail again.
&en`unban-not-banned %vc=That player is not banned anyway! Use +MAIL/BAN <player> to ban someone from sending mail.

&en`no-msg-number %vc=There is no message number %0.
&en`timeout-set %vc=Timeout for BB '%0' [switch(%1,0,cleared,set to [squish(timestring(%1))])].

&en`bbdesc %vc=You set the desc of BB '%0' to: %1

&en`not-number %vc='%0' is not a valid number.
&en`not-timestring %vc='%0' is not a valid timestring.

&en`edit %vc=You edit your message:

&en`connect-writing %vc=You are currently writing a +mail message. Type +PROOF to see it.

&en`deleted-bb %vc=Messages deleted from BB '%0'.
&en`delete-bb-noforce %vc=You cannot delete messages from a bulletin board unless you use +DELETE/FORCE (or +EXPUNGE) <bb> <range>.

&en`bbheader-new-default %vc=BB Header for '%0' reset.
&en`bbheader-new-arb %vc=BB Header for '%0' set to: %1

&en`bbadmin %vc=You set the admin lock for '%0' to: %1
&en`lock-fail-empty %vc=You can't set the lock to the empty string. Set it to 0 if you want noone to pass it.

&en`ignore-start %vc=You start ignoring the '%0' BB.
&en`ignore-end %vc=You are no longer ignoring the '%0' BB.
&en`ignore-none %vc=You aren't ignoring any bulletin boards at present.
&en`ignore-list %vc=You are currently ignoring the following BBs: %0

&en`config-one %vc=Config option '%0': %1%r%2
&en`no-such-config %vc=There is no config option with that name.
&en`config-all %vc=Type +MAIL/CONFIG <option> for more info on any option:
&en`config-invalid %vc=That is not a valid %0.
&en`config-changed %vc=Value set.


@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ CODE (PROPER) STARTS HERE

&TAG %vb=v(config`tag`value)
@set %vb/tag=public
&MSG %vb=udefault(%vc/en`%0,%0,%1,%2,%3,%4,%5,%6,%7,%8,%9)
@set %vb/msg=public
&MSGX %vb=udefault(%vc/%LANG%`%0,%0,%1,%2,%3,%4,%5,%6,%7,%8,%9)

@set %VB=BEEP:[beep()]
@set %vb/beep=public

&fun.clearregs %vb=setq(0,,1,,2,,3,,4,,5,,6,,7,,8,,9,,a,,b,,c,,d,,e,,f,,g,,h,,i,,j,,k,,l,,m,,n,,o,,p,,q,,r,,s,,t,,u,,v,,w,,x,,y,,z,)

@@ FUN.FORMAT-NAMES - given an address list (%0), format it for displaying. Check online relative to player %1.
&fun.format-names %vb=localize(squish(iter(setq(0,lwho(switch(pmatch(%1),#-*,%vz,#$)))%0,switch(%i0,#*:*,if(pmatch(%i0),if(member(%q0,pmatch(%i0)),ansi(h,ufun(fun.propername,%i0)),ufun(fun.propername,%i0)),ufun(%vb/config`purgedname`value,%i0)),ufun(config`bbformat`value,ufun(fun.is-bb,%i0))))))

@@ FUN.FORMAT-NAME-NOANSI - ditto, but does 1 recipient only, doesn't ansi names
&fun.format-name-noansi %vb=switch(%0,#*:*,if(pmatch(%0),ufun(fun.propername,%0),u(%vb/config`purgedname`value,%0)),ufun(config`bbformat`value,%0))

@@ FUN.FORMAT-NAMES-BB - given a message author (%0), format it appropriately (relative to player %1) for BB %2.
&fun.format-names-bb %vb=udefault(%vd/bb`author`%2,ufun(fun.format-names,%0,%1),%0,%1)

@@ FUN.PROPERNAME - return player %0's name
@@ FUN.PROPERNAME-ENACTOR - return %#'s name.
@@ Both take config option "accents" into account. The four functions after are used by +config. Leave 'em alone :)
&fun.propername %vb=accname(%0)
&fun.propername-enactor %vb=%~
&fun.propername-accents1 %vb=accname(%0)
&fun.propername-enactor-accents1 %vb=%~
&fun.propername-accents0 %vb=name(%0)
&fun.propername-enactor-accents0 %vb=%n

@@ FUN.ISADMIN - is %0 an admin in the mail system?
&FUN.ISADMIN %vb=elock(%!/isadmin,%0)

@@ FUN.PLURAL(<num>,<single>[,<plural>]) - <plural> defaults to <single>s
&FUN.PLURAL %vb=switch(%0,1,%1,switch(%+,<3,%1s,%2))
@set %vb/fun.plural=public

@@ FUN.SETQUIET - Set the %0 register to %1 if possible. Return nothing.
&FUN.SETQUIET %vb=null(setq(%0,%1))

&bb %vd=We put the BB database under here
&bb`name %vd=BB names go under here, properly formatted
&bb`read %vd=BB read locks go under here
&bb`write %vd=BB write locks go under here
&bb`timeout %vd=BB timeouts (in seconds) go under here
&bb`header %vd=BB headers (a ufun to display at the top of +skim) go under here
&bb`desc %vd=A desc of BBs goes under here
&bb`notify %vd=Any online players passing this ufun will be notified of new BB posts
&bb`id %vd=BBs get a numerical ID under here
&bb`id->name %vd=Attrs set by the ID and storing the name go under here, for turning an ID into a name easily.

@@ To make a BB:
@@ set X to "bb.count". Now incr bb.count
@@ NAME is the bb name.
@@ make bb`name`NAME %vd=NAME
@@ make bb`read`NAME %vd=some ufun
@@ make bb`write`NAME %vd=some ufun
@@ make bb`notify`NAME %vd=some ufun
@@ make bb`admin`NAME %vd=some ufun
@@ make bb`header`NAME %vd=the bb_header config option
@@ make bb`timeout`NAME %vd=seconds count. Default to 1 week - 604800
@@ make bb`desc`NAME %vd=A desc of the BB
@@ make bb`id`NAME %vd=X
@@ make bb`id->name`X %vd=NAME
@@ @lock/user:bb-read-X %vd=bb`read`NAME/1
@@ @lock/user:bb-write-X %vd=bb`write`NAME/1
@@ @lock/user:bb-notify-X %vd=bb`notify`NAME/1
@@ @lock/user:bb-admin-X %vd=bb`admin`NAME/`

@@ Start on 2, -not- 1, so we can match LOCK-*-<num> without matching the LOCK-*--1 locks
@@ Use the default() so that we don't nuke the old value when upgrading.
@set %vd=bb.count:[default(%vd/bb.count,2)]

&mg %vd=Mailgroup info is stored under here
&mg`name %vd=Names go under here, properly formatted
&mg`lock %vd=People in the mailgroup go under here.

@@ This is a safety against any small slipups in the BB code :)
@lock/user:bb-read--1 %vd=#FALSE
@lock/user:bb-write--1 %vd=#FALSE
@lock/user:bb-notify--1 %vd=#FALSE
@lock/user:bb-admin--1 %vd=#FALSE

@@ FUN.IS-MG - return the real name of the %0 MG, or an empty string if there isn't one
&fun.is-mg %vb=default(%vd/mg`name`%0,)

@@ FUN.IS-MG-BOOL
&fun.is-mg-bool %vb=t(strlen(ufun(fun.is-mg,%0)))

@@ FUN.VALID-MG - is %0 a valid MG name? Let's just use the same rules as for BB names,
@@ since the same restrictions (eval-rules, valid attr name, etc etc) are sensible..
&fun.valid-mg %vb=ufun(fun.valid-bb,%0)

@@ FUN.VALID-BB - Is %0 a valid BB name? If you change this, make sure...
@@ It cannot include "^", "|" or ":" characters, or spaces. It must be a valid attr name. It must not match "0" overall.
@@ It must not contain any characters which are evaluated. Avoiding all those which secure() removes
@@ is a really good idea - they are ( ) [ ] { } $ % , ^ and ; . Also, you can't use the backtick (`) char,
@@ as that will break nastily b/c of attribute trees. You also can't use a BB name which is purely a number.
@@ Sticking with the default is HIGHLY recommended. Allowing BB names only 1 character long is probably
@@ a bad idea, too. You could increase the max BB name length, but it would probably break the formatting of
@@ most BB-listing commands. BB names should not contain colons (:) either.
@@ (This is not a config option deliberately, to discourage people from changing it)
&fun.valid-bb %vb=cand(valid(attrname,%0),regmatch(%0,^\[0-9a-zA-Z_-\]\{2\,14\}$),not(isint(%0)))

@@ FUN.BBNAME-TO-NUM - the id num of BB '%0'
&fun.bbname-to-num %vb=default(%vd/bb`id`[regediti(%0,^(bb:)+,)],if(hasattr(%vd,bb`id->name`%0),%0,-1))

@@ FUN.BBNUM-TO-NAME - the name of BB id '%0'
&fun.bbnum-to-name %vb=default(%vd/bb`id->name`%0,#-1)

@@ FUN.IS-BB - Return the "real" name of BB %0 if it exists, or an empty string
@@ This may be the BB's number, so check for that, too.
&FUN.IS-BB %vb=default(%vd/bb`name`[regediti(%0,^(bb:)+,)],%vd/bb`id->name`%0,)

@@ FUN.IS-BB-BOOL - return 1 if BB %0 exists, 0 otherwise
&FUN.IS-BB-BOOL %vb=t(strlen(ufun(fun.is-bb,%0)))

@@ FUN.CAN-READ-BB - Can player %0 read BB %1?
&FUN.CAN-READ-BB %vb=elock(%vd/BB-READ-[ufun(fun.bbname-to-num,%1)],%0)

@@ FUN.CAN-WRITE-BB - Does player %0 pass the write lock for BB %1?
@@ &FUN.CAN-WRITE-BB %vb=elock(%vd/BB-WRITE-[ufun(fun.bbname-to-num,%1)],%0)
&FUN.CAN-WRITE-BB %vb=cand(member(llocks(%vd),USER:BB-WRITE-[ufun(fun.bbname-to-num,%1)]),elock(%vd/BB-WRITE-[ufun(fun.bbname-to-num,%1)],%0))

@@ FUN.CAN-NOTIFY-BB - Should player %0 be notified of new posts to BB %1?
@@ &FUN.CAN-NOTIFY-BB %vb=elock(%vd/BB-NOTIFY-[ufun(fun.bbname-to-num,%1)],%0)
&FUN.CAN-NOTIFY-BB %vb=cand(member(llocks(%vd),USER:BB-NOTIFY-[ufun(fun.bbname-to-num,%1)]),elock(%vd/BB-NOTIFY-[ufun(fun.bbname-to-num,%1)],%0))

@@ FUN.IS-BB-ADMIN - Is player %0 an admin for BB %1 (can he delete posts from it)?
@@ &FUN.IS-BB-ADMIN %vb=elock(%vd/BB-ADMIN-[ufun(fun.bbname-to-num,%1)],%0)
&FUN.IS-BB-ADMIN %vb=cand(member(llocks(%vd),USER:BB-ADMIN-[ufun(fun.bbname-to-num,%1)]),elock(%vd/BB-ADMIN-[ufun(fun.bbname-to-num,%1)],%0))

@@ FUN.CAN-MAIL-BANNED - Can player %0 send mail (as per +mail/ban)
@@ &FUN.CAN-MAIL-BANNED %vb=andlflags(%0,!MAILBAN !GAGGED !UNREGISTERED)
&FUN.CAN-MAIL-BANNED %vb=andlflags(%0,!MAILBAN)


@@ FUN.CAN-MAIL-GUEST - Can player %0 send mail (because of guest restrictions)?
&FUN.CAN-MAIL-GUEST %vb=nand(haspower(%0,guest),not(get(%vb/config`guests`value)))

@@ FUN.WRITING-MAIL - is %0 currently writing a message?#abc
&fun.writing-mail %vb=sql(SELECT count\(`id`\) FROM `%vpmail` WHERE `who` = '[sqlescape(%0)]' AND `sent` = '0')
@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ FUN.PARSEARGS - parse a (possible) "[@<alt>] [<bb>] [<args>]" string.
@@ The alt ends up as %qA, the bb as %qB and the rest as %qC. Any non-existant args are set empty.
&fun.parseargs %vb=null(regmatchi(%0,v(fun.parseargs2),-1 a b c)[regmatchi(%qb,^(?:bb:)*(.*)$,-1 b)])

@@ Let's try one that DOESN'T need a + before the BB name...
@@ &fun.parseargs2 %vb=^\s*(?:@(\S*))?\s*(?:\+(\S*))?\s*(.*)$
@@ &fun.parseargs2 %vb=^\s*(?:@(\S+))?\s*((?!\S*=|[0-9]*-[0-9]*(?=$|\s)|[0-9]+(?=\s|$))[^ =]+)?\s*(.*)$
&fun.parseargs2 %vb=^\s*(?:@(\S+))?\s*((?:bb:\s+|(?!\S*=|[0-9]*-[0-9]*(?=$|\s)|[0-9]+(?=\s|$))[^ =]+))?\s*(.*)$

@@ FUN.PARSEARGS-NOBB - parse a (possible) "[@<alt>] [<args>]" string.
@@ Alt ends up as %qA, rest as %qC, as above.
&fun.parseargs-nobb %vb=null(regmatchi(%0,v(fun.parseargs-nobb2),-1 a c))
&fun.parseargs-nobb2 %vb=^\s*(?:@(\S*))?\s*(.*)$

@@ FUN.PARSEARGS-NOALT - and one with no alt - that is, "[<bb>] [<args>]".
@@ BB ends up as %qB, the rest as %qC.
&fun.parseargs-noalt %vb=null(regmatchi(%0,v(fun.parseargs-noalt2),-1 b c)[regmatchi(%qb,^(?:bb:)*(.*)$,-1 b)])
@@ &fun.parseargs-noalt2 %vb=^\s*((?!\S*=|[0-9]*-[0-9]*(?=$|\s)|[0-9]+(?=\s|$))[^ =]+)?\s*(.*)$
&fun.parseargs-noalt2 %vb=\s*((?:bb:\s+|(?!\S*=|[0-9]*-[0-9]*(?=$|\s)|[0-9]+(?=\s|$))[^ =]+))?\s*(.*)$

@@ FUN.PARSEARGS-NOARGS - and one with no extra args - that is, "[@<alt>] [<bb>]"
@@ Alt ends up as %qA, BB as %qB
&fun.parseargs-noargs %vb=null(regmatchi(%0,v(fun.parseargs-noargs2),-1 a b))
&fun.parseargs-noargs2 %vb=^\s*(?:@(\S*))?\s*(?:bb:)*(.*)$

@@ FUN.ISALT - is %0 (objid) an alt of %1?
@@ This function must do the following things:
@@  Return -1 if there is no such player as %1.
@@  Return 1 if %1 is the empty string, the same player as %0, or an ALT of %0, or if %3 is true.
@@  Return 0 otherwise.
@@  When not returning -1, the register passed as %2 must be set to the objid of the player matched
@@  (which is just %0, when %1 is the empty string, or objid(pmatch(%1)) otherwise).
&fun.isalt %vb=if(strlen(%1),switch(pmatch(%1),#-*,-1,if(member(ufun(fun.alts,%0),ufun(fun.setquiet,%2,objid(#$))[objid(#$)]),1,t(%3))),ufun(fun.setquiet,%2,%0)1)

@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ FUN.CHECKLOCKS - given an address list (%0) in the form <people>[ufun(%vb/beep)]<bbs>, check to see whose locks
@@ the player %1 passes. Return in the format <good>[ufun(%vb/beep)]<bad>[ufun(%vb/beep)]<errorMsgs>
&fun.checklocks %vb=localize(null(iter(elements(ufun(fun.clearregs)%0,1,setr(x,ufun(%vb/beep))),if(elock(##/mail,%1),setq(0,%q0 ##),setq(1,%q1 ##)[if(cand(hasattrpval(##,mailfailure),strlen(setr(3,ufun(##/mailfailure)))),setq(2,%r[ufun(tag)][ufun(msg,mailfailure,ufun(fun.propername,##),%q3)]))]))[iter(elements(%0,2,%qx),if(ufun(%vb/fun.can-write-bb,%1,%i0),setq(0,%q0 %i0),setq(1,%q1 %i0)))])[setunion(%q0,)]%qx[setunion(%q1,)]%qx[trimpenn(%q2,%r,r)])

@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ FUN.PARSEADDR - parse an address list into a real list of people and BBs. 
@@ Args: %0 = address. %1 = who by? %2 = skip mailgroup checks? Returns
@@ <people>[ufun(%vb/beep)]<bbs>[ufun(%vb/beep)]<errors>. Mailgroups are expanded immediately into lists of people and BBs.
@@ (Errors inside the mailgroups are omitted.) BBs returned are now NUMBERS, and NOT names.
@@ %i0 = this entry, as they typed it. %q1 = this entry, as matched.
@@ %qp = players. %qb = bbs. %qm = mailgroups. %qe = errors and non-matches. %qf - backup of %qe.

@@ Old:
&fun.parseaddr %vb=localize(null(iter(edit(ufun(fun.clearregs)%0,setr(x,ufun(%vb/beep)),),switch(%i0,player:*,if(setr(1,ufun(fun.parseaddr-player,%i0)),setq(P,%q1 %qp),setq(e,%qe %i0)),bb:*,if(strlen(setr(1,ufun(%vb/fun.parseaddr-bb,%i0))),setq(B,%q1 %qb),setq(e,%qe %i0)),mg:*,if(ufun(fun.parseaddr-mg,%i0,%2),,setq(e,%i0 %qe)),switch(1,gt(strlen(setr(1,ufun(fun.parseaddr-bb,%i0))),0),setq(b,%q1 %qb),ufun(fun.parseaddr-mg,%i0,%2),,t(setr(1,ufun(fun.parseaddr-player,%i0))),setq(p,%q1 %qp),setq(e,%qe %i0))))[switch(%qm,,,setq(m,ufun(fun.parseaddr,setunion(iter(%qm,ufun(fun.expand-mg,%i0,%1)),),%1,1)))])[setunion(%qp,elements(%qm,1,%qx))]%qx[setunion(%qb,elements(%qm,2,%qx))]%qx%qe)


@@ New:
&fun.parseaddr %vb=localize(null(iter(edit(ufun(fun.clearregs)%0,setr(x,ufun(%vb/beep)),),switch(%i0,player:*,if(setr(1,ufun(fun.parseaddr-player,%i0)),setq(P,%q1 %qp),setq(e,%qe %i0)),bb:*,if(gt(setr(1,ufun(%vb/fun.parseaddr-bb,%i0)),-1),setq(B,%q1 %qb),setq(e,%qe %i0)),mg:*,if(ufun(fun.parseaddr-mg,%i0,%2),,setq(e,%i0 %qe)),switch(1,gt(setr(1,ufun(fun.parseaddr-bb,%i0)),-1),setq(b,%q1 %qb),ufun(fun.parseaddr-mg,%i0,%2),,t(setr(1,ufun(fun.parseaddr-player,%i0))),setq(p,%q1 %qp),setq(e,%qe %i0))))[switch(%qm,,,setq(m,ufun(fun.parseaddr,setunion(iter(%qm,ufun(fun.expand-mg,%i0,%1)),),%1,1)))])[setunion(%qp,elements(%qm,1,%qx))]%qx[setunion(%qb,elements(%qm,2,%qx))]%qx%qe)


&fun.parseaddr-player %vb=switch(%0,PLAYER:*,objid(pmatch(rest(%0,:))),objid(pmatch(%0)))
&fun.parseaddr-bb %vb=ufun(%vb/fun.bbname-to-num,%0)
@@ If %1 is true, don't parse mailgroups at all. Used to prevent infinite loops.
&fun.parseaddr-mg %vb=if(cand(not(%1),strlen(ufun(fun.is-mg,switch(%0,mg:*,rest(%0,:),%0)))),setq(m,switch(%0,mg:*,rest(%0,:),%0) %qm)1,0)

@@ @@@@@@@@@@@@@@@@@@@
@@ FUN.FORMAT-MESSAGE - display a message
@@ %0 = mailbox num, or -1 for +proof and +read/sent
@@ %1 = mailbox name (BB or objid), unused in +proofs or +read/sent
@@ %2 = mail id
@@ %3 = status - any combination of r (read), n (new), d (deleted), e (eval), s (sent mail)
@@ %4 = author objid
@@ %5 = secs()
@@ %6 = Subject
@@ %7 = recips
@@ %8 = message body & sig
@@ %9 = includes, in format <id>^<author>^secs()^<body&sig>[ufun(%vb/beep)]<id>^<author>^secs()^<body&sig> etc
&fun.format-message %vb=localize(repeat(=,78)%r[switch(ufun(fun.clearregs)%0,-1,switch(%3,*p*,Mail Message In Progress,*s*,Sent Message,Unknown Message),Mail Message [switch(%1,,,ufun(fun.format-name-noansi,%1)%b)]%0)] (Message ID #%2)[switch(setinter(%3,p n e),,,%b%b%b%b---[iter(edit(#$,p,PROOF,e,EXAMINE,n,NEW),##,,\,%b)]---)]%r[ljust(FROM:,9)][switch(%1,,ufun(fun.format-names,%4,%:),#*:*,ufun(fun.format-names,%4,%:),ufun(fun.format-names-bb,%4,%:,%1))] - [convsecs(%5)]%r[ljust(SUBJECT:,9)]%6%r[ljust(TO:,9)][wrap(ufun(fun.format-names,%7,%:),69,69,%r[space(9)])]%r[ljust(ljust(MESSAGE:,9),78,-)]%r[ulocal(fun.format-message-body,%8,%4,member(%3,e))]%r[if(strlen(%9),%r[iter(%9,ansi(n,<Forwarded message originally by [ufun(fun.format-name-noansi,elements(%i0,2,^))] on [timefmt($d-$b-$Y,elements(%i0,3,^))][if(member(%3,e),%b\(#[elements(%i0,1,^)]\))]>)%r[ulocal(fun.format-message-body,rest(rest(rest(%i0,^),^),^),elements(%i0,2,^),member(%3,e))]%r<End of Forwarded Message>,ufun(%vb/beep),%r%r)]%r)][ansi(n,repeat(=,78))])

@@ %0 = body, %1 = author, %2 = noeval?
&fun.format-message-body %vb=if(cand(not(%2),pmatch(%1)),objeval(%1,s(%0)),%0)

@@ %0 = body, %1 = author?, %2 = reader's objid
&fun.format-message-body-as %vb=if(pmatch(%1),s(objeval\(%1\,s\([regeditall(%0,(?<=^|\[^%%\\\\])(%%(\[nNpPsSoOaA~\])),ufun(fun.format-message-body-as-sub,$2,%2))]\)\)),%0)

&fun.format-message-body-as-sub %vb=decompose(case(%0,n,name(%1),N,capstr(name(%1)),~,accname(%1),p,poss(%1),P,capstr(poss(%1)),s,subj(%1),S,capstr(subj(%1)),o,obj(%1),O,capstr(obj(%1)),a,aposs(%1),A,capstr(aposs(%1))))


@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ FUN.FORMAT-SUBJECT - given a subject (%0), alter it to be suitable.
&fun.format-subject %vb=left(localize(switch(setr(0,edit(stripansi(squish(%0)),|,)),,u(%vb/config`default_subject`value),%q0)),60)

@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ FUN.RANGE - given a range of messages, return "1|<ids>|<nums in inbox>" on success, or "0|<errmsg>|?<arg>?" on failure.
@@ Can handle an infinite number of |-separated ranges, where a range is made up of 0 or more of the following
@@ range specs:
@@   author=<player>  - show only messages from <player>
@@   subject=*some_thing* - show only messages with the phrase "some thing" in it (use * for wildcard, _ for space)
@@   mark=[r|d|n] - show only messages which are marked as read, deleted or new, respectively.
@@   status=[r|d|n] - as above
@@   date=123 - show only messages written at time 123
@@   date=<123 - only those written before 123
@@   date=>123 - only those written after 123
@@ author= subject= mark/status= date= x-y

@@ %0 = whose inbox?, %1 = player typing, %2 = range
&fun.range %vb=localize(ufun(fun.clearregs)[setq(e,1)][setq(9,switch(%0,#*:*,sql(SELECT `%vpinbox`.`id` FROM `%vpinbox` INNER JOIN `%vpmail` ON `%vpinbox`.`id`=`%vpmail`.`id` WHERE `%vpinbox`.`who`='%0' ORDER BY `%vpmail`.`date`),sql(SELECT `%vpbbinbox`.`id` FROM `%vpbbinbox` INNER JOIN `%vpmail` ON `%vpbbinbox`.`id`=`%vpmail`.`id` WHERE `%vpbbinbox`.`bbcode`='[setr(b,ufun(%vb/fun.bbname-to-num,%0))]' ORDER BY `%vpmail`.`date`)))][switch(0,strlen(%q9),0|no-messages-[switch(%0,#*:*,switch(%0,%1,you,player),bb)]|%0,setq(r,iter(%2,ufun(fun.range-sub,%i0,%q9,words(%q9),switch(%0,#*:*,player,bb),%1),|,%bOR%b))[t(%qe)],0|[rest(%qe)],words(setr(r,sql(SELECT `%vpmail`.`id` FROM `%vpmail` INNER JOIN [switch(%0,#*:*,`%vpinbox` ON `%vpinbox`.`id`,`%vpbbinbox` ON `%vpbbinbox`.`id`)] = `%vpmail`.`id` WHERE [switch(%qr,,,\(%qr\) AND)] `%vpmail`.`id` IN\([iter(%q9,'##',,\,)]\) AND [switch(%0,#*:*,`%vpinbox`.`who`='%0',`%vpbbinbox`.`bbcode`='%qb')] ORDER BY `%vpmail`.`date`  ))),0|none-in-range,1|[setr(r,sql(SELECT `id` FROM `%vpmail` WHERE `id` IN\([iter(%qr,'##',,\,)]\) ORDER BY `date`))]|[sort(iter(%qr,member(%q9,##)),n)])])

@@ %0 = range, %1 = ids, %2 = num of ids, %3 = 'player' or 'bb', %4 = reader objid
@@ %qe = error, %qa = author, %qs = subject, %qd = date, %qn = numbers, %qm = mark, %q[tu] = temps
&fun.range-sub %vb=iter(setq(a,,s,,d,,n,,m,,t,,u,)%0,if(%qe,switch(%i0,*=*,ufun(fun.range-sub-equals,before(%i0,=),after(%i0,=),%3,%4),if(regmatch(%i0,^(\[0-9\]+|\[0-9\]*-\[0-9\]*)$),setq(n,%qn [ufun(fun.range-numbers,%i0,%2)]),setq(e,#-1 bad-range-spec|%i0)))))([switch(squish(setr(t,%qa %qs %qd %qm) %qn),,1,squish(%qt [switch(%qn,,1,`%vpmail`.`id` IN\([iter(%qn,'[elements(%1,%i0)]',,\,)]\))]))])

@@ %0 = before eq, %1 = after eq, %2 = player/bb, %3 = reader objid
&fun.range-sub-equals %vb=switch(%0,author,if(pmatch(%1),setq(a,%qa `%vpmail`.`who`='[objid(pmatch(%1))]' AND),setq(e,#-1 no-such-player|%1)),subject,setq(s,%qs `%vpmail`.`subject` LIKE '[sqlescape(edit(%1,_,%b,*,get(%vb/config`sql_wildcard`value)))]' AND),mark,ufun(fun.range-sub-status-%2,%1,%3),status,ufun(fun.range-sub-status-%2,%1,%3),date,if(regmatch(%1,^(\[<>\])?(\[0-9\]+)$,-1 t u),setq(d,%qd `%vpmail`.`date` [switch(%qt,,=,%qt)] '[sqlescape(%qu)]' AND),setq(e,#-1 bad-range-date|%q1)),setq(e,#-1 bad-range-spec|%0=%1))

&fun.range-sub-status-player %vb=if(grab(|new|read|deleted,%0*,|),setq(m,%qm `%vpinbox`.`status`='[left(%0,1)]' AND),setq(e,#-1 bad-status|%0))
&fun.range-sub-status-bb %vb=switch(grab(|new|read,%0*,|),,if(grab(|deleted,%0*,|),setq(e,#-1 bad-status-bbdel),setq(e,#-1 bad-status|%0)),setq(m,%qm `%vpbbinbox`.`readers` [switch(#$,new,NOT)] LIKE '[get(%vb/config`sql_wildcard`value)]|%1|[get(%vb/config`sql_wildcard`value)]' AND))

&fun.range-numbers %vb=switch(setdiff(setr(t,switch(%0,-,lnum(1,%1),?*-,lnum(before(%0,-),%1),-?*,lnum(1,after(%0,-)),?*-*?,lnum(before(%0,-),after(%0,-)),%0)),lnum(1,%1)),,%qt,setq(e,#-1 no-msg-number|[first(setdiff(%qt,lnum(1,%1)))]))

@@ @@@@@@@@@@@@@@@@@@@
@@ +MGROUP[/LIST] [<group>]
@@ +MGROUP/EX <group>
@@ +MGROUP/ADD[/noeval] <group>=<list>
@@ +MGROUP/REMOVE <group>
@@ Regex which ignores trailing ='s: $^\+mgroups?(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)?((?\:/l(?\:i(?\:st?)?)?)?|(?\:/ex?)?|(?\:/a(?\:dd?)?)?|(?\:/r(?\:e(?\:m(?\:o(?\:ve?)?)?)?)?)?)?(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)?(?\:\s+(.*[^=]))?=?$:
&cmd.mgroup %va=$^\+mgroups?(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)?((?\:/l(?\:i(?\:st?)?)?)?|(?\:/ex?)?|(?\:/a(?\:dd?)?)?|(?\:/r(?\:e(?\:m(?\:o(?\:ve?)?)?)?)?)?)?(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)?(?\:\s+(.*))?$: @nspemit/silent %#=ufun(%vb/tag)[switch(grab(/list /ex /add /remove,%1*),,ufun(%vb/msg,mgroup-badswitch),ufun(%vb/fun.mgroup[edit(#$,/,-)],%2))]
@set %va/cmd.mgroup=regexp

@@ Find the people %1 will be mailing, when he mails the %0 MG.
&fun.expand-mg %vb=null(elock(%vd/mg-%0,%1))[get(%vd/TEMP`%0`[edit(objid(%1),:,_)])][attrib_set(%vd/TEMP`%0`[edit(objid(%1),:,_)])]

@@ +mgroup/add
&fun.mgroup-add %vb=switch(0,orflags(%#,Wr),ufun(msg,permission-denied),not(strlen(ufun(fun.is-mg,setr(0,before(%0,=))))),ufun(msg,already-a-mg),ufun(fun.valid-mg,%q0),ufun(msg,not-valid-mg),null(set(%vd,mg`name`%q0:%q0)[set(%vd,mg`lock`%q0:[after(%0,=)])][set(%vd,mg`lock2`%q0:[u(fun.mgroup-add-sub,%q0)])][lock(%vd/u:mg-%q0,MG`LOCK2`%q0/1)])[ufun(msg,mgroup-added,%q0)])
&fun.mgroup-add-sub %vb=null\(set\(%%vd,TEMP`%0`\[edit\(objid\(%%#\),:,_\)\]:\[ufun\(MG`LOCK`%0\)\]\)\)1


@@ +mgroup/remove
&fun.mgroup-remove %vb=switch(0,orflags(%#,Wr),ufun(msg,permission-denied),strlen(setr(0,ufun(%vb/fun.is-mg,%0))),ufun(msg,no-such-mg),null(wipe(%vd/mg`*`%q0)[lock(%vd/mg-%q0,)])[ufun(msg,mgroup-removed,%q0)])


@@ +mgroup/ex
&fun.mgroup-ex %vb=switch(0,strlen(setr(0,ufun(%vb/fun.is-mg,%0))),ufun(msg,no-such-mg),ufun(msg,mgroup-ex,%0,get(%vd/mg`lock`%0)))


@@ +mgroup/list
&fun.mgroup-list %vb=switch(0,strlen(%0),ufun(fun.mgroup-list-all),strlen(setr(0,ufun(%vb/fun.is-mg,%0))),ufun(msg,no-such-mg),ufun(msg,mgroup-list,%q0,ufun(fun.format-names,edit(elements(ufun(fun.parseaddr,MG:%0,%:),1 2,beep()),beep(),%b),%:)))
&fun.mgroup-list-all %vb=switch(lattr(%vd/mg`name`*),,ufun(msg,mgroup-none),ufun(msg,mgroup-list-all)[table(iter(lattr(%vd/mg`name`*),get(%vd/##)),19,78)])


@@ ((?\:/l(?\:i(?\:st?)?)?)?|(?\:/ex?)?|(?\:/a(?\:dd?)?)?|(?\:/r(?\:e(?\:m(?\:o(?\:ve?)?)?)?)?)?)?
@@ (?\:/l(?\:i(?\:st?)?)?)?
@@ (?\:/ex?)?
@@ (?\:/a(?\:dd?)?)?
@@ (?\:/r(?\:e(?\:m(?\:o(?\:ve?)?)?)?)?)?

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBCREATE <bb>
&cmd.bbcreate %va=$+bbcreate *: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.bbcreate,%0)]

&fun.bbcreate %vb=switch(0,orflags(%#,Wr),ufun(msg,permissioned-denied),ufun(fun.valid-bb,%0),ufun(msg,invalid-bb-name),not(strlen(ufun(fun.is-bb,%0))),ufun(msg,bbcreate-existing),ufun(fun.bbcreate-sub,%0)[ufun(msg,new-bb,%0)])

@@ The user: prefix for lock() is abbreviated to u: to avoid a bug in lock() in 1.8.1p1
&fun.bbcreate-sub %vb=null(setq(0,get(%vd/bb.count))[set(%vd,bb.count:[inc(%q0)])][set(%vd,bb`name`%0:%0)][set(%vd,bb`id->name`%q0:%0)][set(%vd,bb`read`%0:0)][set(%vd,bb`write`%0:0)][set(%vd,bb`notify`%0:0)][set(%vd,bb`timeout`%0:[get(%vb/config`bb_timeout`value)])][set(%vd,bb`desc`%0:%0 BB)][set(%vd,bb`id`%0:%q0)][lock(%vd/u:bb-read-%q0,bb`read`%0/1)][lock(%vd/u:bb-write-%q0,bb`write`%0/1)][lock(%vd/u:bb-notify-%q0,bb`notify`%0/1)][lock(%vd/u:bb-admin-%q0,bb`admin`%0/1)][set(%vd,bb`header`%0:[ufun(%vb/config`bb_header`value,%0)])[attrib_set(%vd/bb`author`%0)]])

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBAUTHOR <bb>=<function>
&cmd.bbauthor %va=$^\+bbauthor(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)? ([^=]*?)(?\:=(.*))?$: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.bbauthor,%1,%2)]
@set %va/cmd.bbauthor=regexp

&fun.bbauthor %vb=switch(0,strlen(setr(0,ufun(%vb/fun.is-bb,%0))),ufun(msg,no-such-bb,%0,),cor(orflags(%#,Wr),ufun(fun.is-bb-admin,%:,%q0)),ufun(msg,permission-denied),strlen(%1),attrib_set(%vd/bb`author`%q0)[ufun(msg,bbauthor-cleared,%q0)],attrib_set(%vd/bb`author`%q0,%1)[ufun(msg,bbauthor-set,%q0,%1)])

&en`bbauthor-cleared %vc=Author for BB '%0' cleared.
&en`bbauthor-set %vc=Author for BB '%0' set to '%1'.

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBHEADER <bb>=<header>
&cmd.bbheader %va=$^\+bbheader(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)? ([^=]*?)(?\:=(.*))?$: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.bbheader,%1,%2)]
@set %va/cmd.bbheader=regexp

&fun.bbheader %vb=switch(0,strlen(setr(0,ufun(%vb/fun.is-bb,%0))),ufun(msg,no-such-bb,%0),cor(orflags(%#,Wr),ufun(fun.is-bb-admin,%:,%q0)),ufun(msg,permission-denied),strlen(%1),set(%vd,bb`header`%q0:[ufun(%vb/config`bb_header`value,%q0)])[ufun(msg,bbheader-new-default,%q0)],set(%vd,bb`header`%0:%1)[ufun(msg,bbheader-new-arb,%q0,%1)])

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBDESC <bboard>=<desc>
&cmd.bbdesc %va=$+bbdesc *=*: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.bbdesc,%0,%1)]

&fun.bbdesc %vb=switch(0,orflags(%#,Wr),ufun(msg,permission-denied),ufun(fun.is-bb,%0),ufun(msg,no-such-bb,%0),set(%vd,bb`desc`%0:%1)[ufun(msg,bbdesc,get(%vd/bb`name`%0),%1)])


@@ @@@@@@@@@@@@@@@@@@@
@@ +BBDELETE <bb>
&cmd.bbdelete %va=$+bbdelete *: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.bbdelete,%0)]

&fun.bbdelete %vb=switch(0,orflags(%#,Wr),ufun(msg,permission-denied),strlen(setr(0,ufun(fun.is-bb,%0))),ufun(msg,no-such-bb,%0),ufun(msg,bbdelete,%q0)[ufun(fun.bbdelete-sub,%0)])

&fun.bbdelete-sub %vb=null(setq(0,ufun(fun.bbname-to-num,%0))[wipe(%vd/bb`*`%0)][wipe(%vd/bb`id->name`%q0)][sql(DELETE FROM `%vpbbinbox` WHERE `bbcode` = '%q0')][iter(graball(locks(%vd),USER:BB-*-%q0),lock(%vd/##,))])


@@ @@@@@@@@@@@@@@@@@@@
@@ +BBTIMEOUT <bb>=<timeout>
&cmd.bbtimeout %va=$+bbtimeout *=*: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.bbtimeout,%0,%1)]

&fun.bbtimeout %vb=switch(0,strlen(setr(0,ufun(fun.is-bb,%0))),ufun(msg,no-such-bb,%0),orflags(%#,Wr),ufun(msg,permission-denied),not(strmatch(setr(1,stringsecs(%1)),#-*)),ufun(msg,not-timestring,%1),set(%vd,bb`timeout`%0:%q1)[ufun(msg,timeout-set,%q0,%q1)])


@@ @@@@@@@@@@@@@@@@@@@
@@ +BBLOCK[/write|/read|/notify] <bb>=<ufun>
&cmd.bblock %va=$^\+bblock(?\:/noe(?\:v(?\:al?)?)?)?(?\:/(\S*?))?(?\:/noe(?\:v(?\:al?)?)?)? ([^=]+)=(.*)$: @nspemit/silent %#=ufun(%vb/tag)[switch(,%1,ufun(%vb/fun.bblock,Read,%2,%3),setr(0,first(iter(%1,grab(|Read|Write|Notify|Post,%i0*,|),/,%b))),ufun(%vb/msg,bblock-bad-switch),ufun(%vb/fun.bblock,edit(%q0,Post,Write),%2,%3))]
@set %va/cmd.bblock=regexp
&fun.bblock %vb=switch(0,strlen(setr(0,ufun(fun.is-bb,%1))),ufun(msg,no-such-bb,%1),orflags(%#,Wr),ufun(msg,permission-denied),strlen(squish(%2)),ufun(msg,lock-fail-empty),set(%vd,bb`%0`%q0:%2)[ufun(msg,bblock-set,%0,%q0,%2)])

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBADMIN <bb>=<ufun>
&cmd.bbadmin %va=$^\+bbadmin(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)? +([^=]+)(?\:=(.*))?: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.bbadmin,%1,%2)]
@set %va/cmd.bbadmin=regexp

&fun.bbadmin %vb=switch(0,strlen(setr(0,ufun(fun.is-bb,%0))),ufun(msg-no-such-bb,%0),orflags(%:,Wr),ufun(msg,permission-denied),strlen(squish(%1)),ufun(msg,lock-fail-empty),set(%vd,bb`admin`%q0:%1)[ufun(msg,bbadmin,%q0,%1)])


@@ @@@@@@@@@@@@@@@@@@@
@@ +BBINFO <bb>
&cmd.bbinfo %va=$+bbinfo *: @nspemit/silent %#=if(strlen(setr(0,ufun(%vb/fun.is-bb,%0))),ufun(%vb/fun.bbinfo,%q0),ufun(%vb/tag)[ufun(%vb/msg,no-such-bb,%0)])

&fun.bbinfo %vb=%r[ufun(%vd/bb`header`%0)]%rName: [get(%vd/bb`name`%0)]%rNumber: [get(%vd/bb`id`%0)]%r[if(hasattrval(%vd,bb`desc`%0),Desc: [get(%vd/bb`desc`%0)]%r)]Timeout: [switch(default(%vd/bb`timeout`%0,0),0,None,timestring(get(%vd/bb`timeout`%0)))]%rRead Lock: [get(%vd/bb`read`%0)]%rWrite Lock: [get(%vd/bb`write`%0)]%rNotify Lock: [get(%vd/bb`notify`%0)][if(hasattrval(%vd,bb`admin`%0),%rAdmin Lock: [get(%vd/bb`admin`%0)])][if(ufun(fun.can-read-bb,%:,%0),%rMessages Posted: [sql(SELECT count(`id`) FROM `%vpbbinbox` WHERE `bbcode` = '[ufun(fun.bbname-to-num,%0)]')])]%rBB Header: [get(%vd/bb`header`%0)]%r[repeat(=,78)]

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBLIST[/all] [@<alt>]
&cmd.bblist %va=$^\+bblist([ /]a(?\:ll?)?)?(?\: (.+))?$: @nspemit/silent %#=ufun(%vb/fun.parseargs,%2)[switch(ufun(%vb/fun.isalt,%:,%qa,a,1),-1,ufun(%vb/tag)[ufun(%vb/msg,no-such-player,%qa)],0,ufun(%vb/tag)[ufun(%vb/msg,not-an-alt,%qa)],ufun(%vb/fun.bblist-[if(%1,all,some)],%qa))]
@set %va/cmd.bblist=regexp

&fun.bblist-some %vb=switch(0,words(setr(0,squish(iter(edit(lattr(%vd/bb`name`*),BB`NAME`,),if(ufun(%vb/fun.can-read-bb,%0,##),get(%vd/bb`id`##)^[get(%vd/bb`name`##)]^[sql(SELECT count(`id`) FROM `%vpbbinbox` WHERE `bbcode` = '[ufun(fun.bbname-to-num,##)]')]),,|),|)),|),ufun(tag)[ufun(msg,bb-noread)],ufun(if(hasattr(%vb,skin`bblist),skin`bblist,fun.bblist-show),ufun(msg,bblist-some),%q0))

&fun.bblist-all %vb=ufun(if(hasattr(%vb,skin`bblist),skin`bblist,fun.bblist-show),u(msg,bblist-all),iter(edit(lattr(%vd/bb`name`*),BB`NAME`,),get(%vd/bb`id`##)^[get(%vd/bb`name`##)]^[if(ufun(fun.can-read-bb,%0,##),sql(SELECT count(`id`) FROM `%vpbbinbox` WHERE `bbcode` = '[ufun(fun.bbname-to-num,##)]'))],,|))

@@ Ala the SKIN`BB[list|scan] attrs, %0 is a text message and %1 is a bbNum^bbName^numNewPosts, |-separated list
@@ This is "default skin" for both +bblist and +bbscan.
&fun.bblist-show %vb=ufun(%vb/tag)%0%r[repeat(=,78)]%r[table(iter(%1,rjust(first(##,^),3). %b[elements(##,2,^)][switch(last(##,^),,,%b(#$))],|,|),25,78,|)]%r[repeat(=,78)]

@@ SKIN ATTRIBUTE: %vb/SKIN`BBLIST
@@ ARGS RECEIVED: %0 is the message to display (without [+MAIL] tag).
@@                %1 is a | separated list, in the format bbNumber^bbName^newPosts
@@ Example 1 (which doesn't show BB numbers):
&skin`bblist %vb=ufun(%vb/tag)%0%r[repeat(=,78)]%r[table(iter(%1,%b[elements(##,2,^)] [switch(last(##,^),,,%b(#$))],|,|),25,78,|)]%r[repeat(=,78)]

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBSCAN [@<alt>]
&cmd.bbscan %va=$+bbscan*: @nspemit/silent %#=ufun(%vb/fun.bbscan,%0)

@@ Args: %0 = args (for @<alt>). If %1 is true we don't show a "no new messages" message, for the @aconnect
&fun.bbscan %vb=ufun(fun.parseargs,%0)[switch(ufun(fun.isalt,%:,%qa,a,1),-1,ufun(%vb/tag)[ufun(msg,no-such-player,%qa)],0,ufun(%vb/tag)[ufun(msg,not-an-alt,%qa)],switch(0,words(setr(0,filterbool(#lambda/ufun(%vb/fun.can-read-bb,%:,first(%%0)),sql(SELECT `bbcode`\, COUNT(*) FROM `%vpbbinbox` WHERE `readers` NOT LIKE '[get(%vb/config`sql_wildcard`value)]|%qa|[get(%vb/config`sql_wildcard`value)]' AND `bbcode` NOT IN([iter(regraball(default(%qa/BBIGNORE,-1) -1,^-?\[0-9\]+$),'##',,\,)]) GROUP BY `bbcode`,^,%b),^))),if(%1,,ufun(%vb/tag)[ufun(msg,bbscan-nonew)]),[ufun(if(hasattrval(%vb,skin`bbscan),skin`bbscan,fun.bblist-show),ufun(msg,bbscan),iter(%q0,first(##)^[ufun(fun.bbnum-to-name,first(##))]^[rest(##)],^,|))]))]


@@ SKIN ATTRIBUTE: %vb/SKIN`BBSCAN
@@ ARGS RECEIVED: %0 is the message to display (without [+MAIL] tag).
@@                %1 is a | separated list, in the format bbNumber^bbName^newPosts
@@ Example 1 (which skips how many new posts there are):
@@  &skin`bbscan %vb=%0%r[center(%bBBSCAN%b,78,~=)]%r[table(iter(%1,rjust(first(##,^),3).)--[elements(##,2,^)],|,|),19,78,|)]%r[repeat(=,78)]
@@ Example 2 (which doesn't show BB numbers):
@@  &skin`bbscan %vb=ufun(%vb/tag)%0%r[repeat(=,78)]%r[table(iter(%1,%b[elements(##,2,^)] ([elements(##,3,^)]),|,|),19,78,|)]%r[repeat(=,78)]

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBIGNORE <bb>
@@ A toggle; don't list <bb> in a +bbscan (or do, when we toggle it back on)
&cmd.bbignore %va=$+bbignore*: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.bbignore-sanity,%:)][ufun(%vb/fun.bbignore[switch(%0,,-list,-toggle)],squish(%0))]
&cmd.bbleave %va=$+bbleave*: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.bbignore-sanity,%:)][ufun(%vb/fun.bbignore[switch(%0,,-list,-toggle)],squish(%0))]

@@ remove any invalid strings from %0's BBIGNORE attr
&fun.bbignore-sanity %vb=set(%0,BBIGNORE:[iter(regraball(get(%0/BBIGNORE),^\[0-9\]+$),if(hasattr(%vd,bb`id->name`##),##))])

&fun.bbignore-list %vb=switch(get(%:/bbignore),,ufun(msg,ignore-none),ufun(msg,ignore-list,itemize(iter(#$,ufun(fun.bbnum-to-name,##)))))

&fun.bbignore-toggle %vb=switch(0,strlen(setr(0,ufun(fun.is-bb,%0))),ufun(msg,no-such-bb),member(get(%:/bbignore),setr(1,ufun(fun.bbname-to-num,%q0))),set(%:,bbignore:[setunion(get(%:/bbignore),%q1)])[ufun(msg,ignore-start,%q0)],switch(setr(2,setdiff(get(%:/bbignore),%q1)),,attrib_set(%:/bbignore),attrib_set(%:/bbignore,%q2))[ufun(msg,ignore-end,%q0)])

@@ @@@@@@@@@@@@@@@@@@@
@@ +ADDRESS <address>
&cmd.address %va=$+address *: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.address,%0)]

&fun.address %vb=switch(0,ufun(%vb/fun.writing-mail,%:),ufun(msg,not-writing),comp(setr(x,ufun(%vb/beep))%qx,left(setr(a,ufun(fun.parseaddr,%0,%:)),2)),ufun(msg,no-good-players,after(%qa,%qx%qx)),switch(setr(t,elements(%qa,3,%qx)),?*,ufun(msg,these-players-bad,%qt)%r[u(tag)])[switchall(0,strlen(elements(setr(1,ufun(fun.checklocks,%qa,%0)),1,%qx)),ufun(msg,fail-locks-all,ufun(fun.format-names,elements(%q1,2,%qx),%0))[elements(%q1,3,%qx)],not(strmatch(%ql,?*%qx?*%qx*)),ufun(msg,fail-locks-some,u(fun.format-names,elements(%q1,2,%qx),%0))[elements(%q1,3,%qx)]%r[u(tag)],not(strlen(elements(%q1,1,%qx))),ufun(fun.address-sub,elements(%q1,1,%qx)))])

&fun.address-sub %vb=null(sql(UPDATE `%vpmail` SET `recip` = '[sqlescape(%0)]' WHERE `who` = '[sqlescape(%:)]' AND `sent` = '0'))[ufun(msg,address-changed,ufun(fun.format-names,%0,%:))]

@@ @@@@@@@@@@@@@@@@@@@
@@ +CC <address>
@@ +CC/REMOVE <address>
&cmd.cc %va=$^\+cc(/r(?\:e(?\:m(?\:o(?\:ve?)?)?)?)?)? (.+)$: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.cc[switch(%1,?*,-remove)],%2)]
@set %va/cmd.cc=regexp

@@ Player %: wants to add %0 to his mail's address
&fun.cc %vb=switch(0,ufun(%vb/fun.writing-mail,%:),ufun(msg,not-writing),comp(setr(x,ufun(%vb/beep))%qx,left(setr(a,ufun(fun.parseaddr,%0,%:)),2)),ufun(msg,no-good-players,after(%qa,%qx%qx)),switch(setr(t,elements(%qa,3,%qx)),?*,ufun(msg,these-players-bad,%qt)%r[ufun(tag)])[switchall(0,strlen(elements(setr(l,ufun(fun.checklocks,%qa,%:)),1,%qx)),ufun(msg,fail-locks-all,ufun(fun.format-names,elements(%ql,2,%qx),%:))[elements(%ql,3,%qx)],not(strmatch(%ql,?*%qx?*%qx*)),ufun(msg,fail-locks-some,ufun(fun.format-names,elements(%ql,2,%qx),%:))[elements(%ql,3,%qx)]%r[u(tag)],not(strlen(elements(%ql,1,%qx))),ufun(fun.cc-sub,sqlescape(%:),elements(%ql,1,%qx)))])

&fun.cc-sub %vb=null(sql(UPDATE `%vpmail` SET `recip` = '[sqlescape(setunion(%1,setr(0,sql(SELECT `recip` FROM `%vpmail` WHERE `who` = '%0' AND `sent` = '0'))))]' WHERE `who` = '%0' AND `sent` = '0'))[ufun(msg,address-changed,ufun(fun.format-names,setunion(%1,%q0),%0))]

&fun.cc-remove %vb=switch(0,ufun(%vb/fun.writing-mail,%:),ufun(msg,not-writing),comp(setr(x,ufun(%vb/beep))%qx,left(setr(a,ufun(fun.parseaddr,%0,%:)),2)),ufun(msg,no-good-players,after(%qa,%qx%qx)),if(strmatch(%qa,*%qx*%qx),,ufun(msg,these-players-bad,elements(%qa,3,%qx))%r[u(tag)])[ufun(fun.cc-remove-sub,sqlescape(%:),setunion(elements(%qa,1,%qx),elements(%qa,2,%qx)))])

&fun.cc-remove-sub %vb=setq(0,sql(SELECT `recip` FROM `%vpmail` WHERE `who` = '%0' AND `sent` = '0'))[switch(,setinter(%q0,%1),ufun(msg,cc-remove-who),setdiff(%q0,%1),ufun(msg,cc-remove-all),null(sql(UPDATE `%vpmail` SET `recip` = '[sqlescape(setdiff(%q0,%1))]' WHERE `who` = '%0' AND `sent` = '0'))[ufun(msg,address-changed,ufun(fun.format-names,setdiff(%q0,%1),%0))])]

@@ @@@@@@@@@@@@@@@@@@@
@@ +MAIL/PURGE
@@ cmd.mail handles this

&fun.purge %vb=if(orflags(%#,Wr),ufun(fun.purge-sub)[ufun(msg,purged)],ufun(msg,permission-denied))

&fun.purge-sub %vb=null(sql(DELETE FROM `%vpbbinbox` WHERE [setq(0,secs())][iter(setunion(regeditall(setr(0,sql(SELECT `%vpbbinbox`.`bbcode`\, `%vpbbinbox`.`id` FROM `%vpbbinbox` INNER JOIN `%vpmail` ON `%vpmail`.`id` = `%vpbbinbox`.`id` WHERE [iter(lattr(%vd/bb`id->name`*),(`%vpbbinbox`.`bbcode` = '[last(##,`)]' AND `%vpmail`.`date` < [sub(%q0,switch(default(%vd/bb`timeout`[get(%vd/##)],0),0,%q0,get(%vd/bb`timeout`[get(%vd/##)])))]),,%bOR%b)],%b,^)),\\^\\S+,),),(`bbcode` = '##' AND `id` IN([squish(regeditall(graball(%q0,##^*),\\S+\\^(\\S+),'$1'\,))]'#-2')),,%bOR%b)])[sql(DELETE FROM `%vpmail` WHERE `id` IN([squish(regeditalli(sql(SELECT P.ID FROM `%vpmail` P LEFT JOIN `%vpinbox` ON P.id = `%vpinbox`.ID LEFT JOIN `%vpbbinbox` ON P.id = `%vpbbinbox`.ID LEFT JOIN `%vpmail` C ON C.forwards LIKE concat('%%|'\,P.id\,'|%%') WHERE `%vpinbox`.ID IS NULL AND `%vpbbinbox`.ID IS NULL AND C.forwards IS NULL LIMIT 100,%b,%b),\\S+,$0\,))]'#-2'))][sql(DELETE FROM `%vpinbox` WHERE `who` IN([squish(iter(sql(SELECT DISTINCT `who` FROM `%vpinbox`),if(pmatch(##),,'##'\,)))]'#-2'))])

@@ @@@@@@@@@@@@@@@@@@@
@@ PURGE LOOP

@STARTUP %vb=@halt me=@trigger me/trg.purge

&TRG.PURGE %vb=THINK ufun(fun.purge-sub) ; @wait 86400=@TRIGGER ME/TRG.PURGE

@@ fun.purge-sub is with the +mail/purge command, just above.

@@ @@@@@@@@@@@@@@@@@@@
@@ +MAIL/CONFIG [<option>[=<value>]]
@@ cmd.mail handles this

&fun.config %vb=switch(%0,*=*,if(hasflag(%#,WIZARD),ufun(fun.config-set,before(%0,=),after(%0,=)),ufun(msg,permission-denied)),,ufun(fun.config-list-all),ufun(fun.config-list-one,%0))

&fun.config-set %vb=switch(0,hasattrval(%vb,config`%0`value),ufun(msg,no-such-config),strlen(setr(0,ufun(fun.config-validate,%1,get(%vb/config`%0`type)))),ufun(msg,config-invalid,switch(get(%vb/config`%0`type),time,timestring,get(%vb/config`%0`type))),null(ufun(%vb/config`%0`onchange,%q0)[set(%vb,config`%0`value:%q0)])[ufun(msg,config-changed)])

@@ string bool int time
&fun.config-validate %vb=switch(%1,string,%0,int,ufun(fun.config-validate-num,%0),time,ufun(fun.config-validate-time,%0),bool,ufun(fun.config-validate-bool,%0))
&fun.config-validate-bool %vb=switch(%0,1,1,0,0,yes,1,no,0,true,1,false,0)
&fun.config-validate-num %vb=if(regmatch(%0,^\[0-9\]+$),%0)
&fun.config-validate-time %vb=switch(stringsecs(%0),#-*,,#$)

&fun.config-list-all %vb=ufun(msg,config-all)%r[iter(lcstr(lattr(%vb/config`*)),ljust(after(##,`),20)[ufun(%vb/fun.config-format,get(%vb/##`value),get(%vb/##`type))],,%r)]

&fun.config-list-one %vb=if(hasattrval(%vb,config`%0`value),ufun(msg,config-one,lcstr(%0),ufun(%vb/config`%0),ufun(fun.config-format,get(%vb/config`%0`value),get(%vb/config`%0`type))),ufun(msg,no-such-config))

&fun.config-format %vb=switch(%1,time,timestring(%0),bool,if(%0,Yes,No),%0)


@@ @@@@@@@@@@@@@@@@@@@
@@ +MAIL/BAN <player>
@@ cmd.mail handles this

&fun.ban %vb=switch(0,orflags(%#,Wr),ufun(msg,permission-denied),t(setr(0,pmatch(%0))),ufun(msg,no-such-player,%0),hasflag(%q0,MAILBAN),set(%q0,MAILBAN)[nspemit(%q0,ufun(tag)[ufun(msg,ban-banned)])][ufun(msg,ban-you-banned,name(%q0),%q0)],ufun(msg,ban-already-banned))


@@ @@@@@@@@@@@@@@@@@@@
@@ +MAIL/UNBAN <player>
@@ cmd.mail handles this

&fun.unban %vb=switch(0,orflags(%#,Wr),ufun(msg,permission-denied),t(setr(0,pmatch(%0))),ufun(msg,no-such-player,%0),hasflag(%q0,MAILBAN),ufun(msg,unban-not-banned),set(%q0,!MAILBAN)[nspemit(%q0,ufun(tag)[ufun(msg,ban-unbanned)])][ufun(msg,ban-you-unban,name(%q0),%q0)])


@@ @@@@@@@@@@@@@@@@@@@
@@ +MAIL/BANNED
@@ cmd.mail handles this

&fun.banned %vb=switch(0,orflags(%#,Wr),ufun(msg,permisssion-denied),t(setr(0,lsearch(all,lflags,MAILBAN))),ufun(msg,none-banned),ufun(msg,banned,ufun(fun.format-names,iter(%q0,objid(##)),%:)))


@@ @@@@@@@@@@@@@@@@@@@@
@@ +MAIL - any and ALL commands which start '+mail', with or without switches, are
@@         powered through here.
@@ Allowed switches: ban, unban, banned, config, purge, version
@@ +mail, +mail addr=subj, +mail/[un]ban, +mail/banned, +mail/config, +mail/purge, +mail/version
@@ Regexp which ignored trailing ='s: $^\+mail(/\S*)?(?\: +(.*[^=])?)?=?$: 
&cmd.mail %va=$^\+mail(/\S*)?(?\: +(.*))?$: @nspemit/silent %#=ufun(%vb/tag)[switch(first(setunion(iter(%1,grab(|ban|banned|config|purge|unban|version,%i0*,|),/,%b),)),,switch(0,lte(strlen(%1),1),ufun(%vb/msg,unknown-mail-switch),match(%2,*=*),ufun(%vb/fun.mail-check,%:,%2),ufun(%vb/fun.mail-start,before(%2,=),after(%2,=))),ufun(%vb/fun.#$,%2))]
@set %va/cmd.mail=regexp


@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ +MAIL/VERSION (called from cmd.mail)
&fun.version %vb=VERSION INFO:%r[ufun(describe)]

@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ +mail [@<alt>] [<bb>]
@@ +mail[/noeval] <address>=<subject>
@@ cmd.mail handles these

@@ FUN.MAIL-CHECK - for player %0, check he can find messages (with args %1) and show info.
&fun.mail-check %vb=ufun(fun.parseargs-noargs,%1)[switch(ufun(%vb/fun.isalt,%0,%qa,a),-1,ufun(msg,no-such-player,%qa),0,ufun(msg,not-an-alt,%qa),switch(,%qb,ufun(fun.mail-check-info,%qa,%0),setr(C,ufun(fun.is-bb,%qb)),ufun(msg,no-such-bb,%qb),if(ufun(fun.can-read-bb,%qa,%qc),ufun(fun.mail-check-info,%qc,%qa),ufun(msg,cant-read-bb,%qc))))]

@@ FUN.MAIL-CHECK-INFO - show mail in inbox of %0. %1 is the objid of the person checking it.
&fun.mail-check-info %vb=switch(%0,#*:*,ufun(msg,player[switch(%0,%1,-same)]-check,%0,words(setr(0,sql(SELECT `status` FROM `%vpinbox` WHERE `who` = '%0'))),words(graball(%q0,n)),words(graball(%q0,r)),words(graball(%q0,d))),ufun(msg,board-check,%0,words(setr(0,sql(SELECT CASE WHEN INSTR(`readers`,'|%1|') > 0 THEN 'r' ELSE 'n' END FROM `%vpbbinbox` WHERE `bbcode` = '[ufun(fun.bbname-to-num,%0)]'))),words(graball(%q0,n))))

@@ @ACONNECT %va=@wait 1=@nspemit/silent %#=switchall(1,setr(0,get(%vb/config`connect_mail`value)),ulocal(%vb/tag)[ulocal(%vb/fun.mail-check-info,%:,%:)],cand(%q0,setr(1,get(%vb/config`connect_bb`value))),%r,%q1,ulocal(%vb/fun.bbscan))

@ACONNECT %va=@wait 1=@nspemit/silent %#=allof(if(get(%vb/config`connect_mail`value),ulocal(%vb/tag)[ulocal(%vb/fun.mail-check-info,%:,%:)]),if(get(%vb/config`connect_bb`value),ulocal(%vb/fun.bbscan,,1)),if(ufun(%vb/fun.writing-mail,%:),ulocal(%vb/tag)[ufun(%vb/msg,connect-writing)]),%r)


@@ FUN.MAIL-START- Player %: is trying to send mail to %0 called %1. Check it's allowed, etc. Called only from
@@ the +mail command. Does not actually send the mail itself.
@@
@@ Things to think about:
@@ 1) Make sure %0 isn't already sending mail
@@ 2) Make sure %0 isn't a guest who is banned from sending mail, or banned through +mail/ban
@@ 3) Parse the address list, make sure we have someone valid, whose locks we pass.
@@ 4) Check the subject. First, stripansi() it. Then squish() it. If it's 0-length, use the default.
@@ 
&fun.mail-start %vb=switch(0,ufun(fun.can-mail-guest,%:),ufun(msg,no-guest-mail),not(ufun(fun.writing-mail,%:)),ufun(msg,already-writing),ufun(fun.can-mail-banned,%:),ufun(msg,banned-from-mailing),not(strmatch(setr(a,ufun(fun.parseaddr,%0,%:)),setr(x,ufun(%vb/beep))%qx*)),ufun(msg,no-good-players,after(%qa,%qx%qx)),switch(setr(t,elements(%qa,3,%qx)),?*,ufun(msg,these-players-bad,%qt)%r[ufun(tag)])[switchall(0,strlen(elements(setr(l,ufun(fun.checklocks,%qa,%:)),1,%qx)),ufun(msg,fail-locks-all,ufun(fun.format-names,elements(%ql,2,%qx),%:))[elements(%ql,3,%qx)],not(strmatch(%ql,?*%qx?*%qx*)),ufun(msg,fail-locks-some,ufun(fun.format-names,elements(%ql,2,%qx),%:))[elements(%ql,3,%qx)]%r[u(tag)],not(strlen(elements(%ql,1,%qx))),ufun(msg,new-msg,ufun(fun.mail-start-sub,%:,%1,elements(%ql,1,%qx))))])

&fun.mail-start-sub %vb=null(sql(u(fun.mail-start-sub-query,%0,%1,%2)))[sql(SELECT last_insert_id())]

&fun.mail-start-sub-query %vb=INSERT INTO `%vpmail`(`who`,`date`,`subject`,`recip`,`sent`,`forwards`) VALUES('[sqlescape(%0)]','[sqlescape(secs())]','[sqlescape(ufun(fun.format-subject,%1))]','[sqlescape(%2)]','0','||')

@@ @@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@
@@ +REPLY [@<alt>] [<bb>] <range>
&cmd.reply %va=$+reply *: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.reply,%0)]

@@ Player %: typed '+reply %0'
&fun.reply %vb=ufun(fun.parseargs,%0)[switch(ufun(%vb/fun.isalt,%:,%qa,a),-1,ufun(msg,no-such-player,%qa),0,ufun(msg,not-an-alt,%qa),switch(0,ufun(fun.can-mail-guest,%:),ufun(msg,no-guest-mail),not(ufun(fun.writing-mail,%:)),ufun(msg,already-writing),ufun(fun.can-mail-banned,%:),ufun(msg,banned-from-mailing),strlen(%qc),ufun(msg,reply-to-which),strlen(%qb),ufun(fun.reply-sub,%:,%qa,%qc),strlen(setr(1,ufun(fun.is-bb,%qb))),ufun(msg,no-such-bb,%qb),if(ufun(fun.can-read-bb,%qa,%q1),ufun(fun.reply-sub,%:,%q1,%qc),ufun(msg,cant-read-bb,%q1))))]

@@ Player %0 is trying to reply to message range %2 in inbox belonging to %1.
&fun.reply-sub %vb=switch(0,first(setr(0,ufun(fun.range,%1,%0,%2)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),eq(words(setr(i,elements(%q0,2,|))),1),ufun(msg,reply-to-one,words(%qi)),not(strmatch(setr(a,ufun(fun.parseaddr,null(regmatch(sql(SELECT CONCAT(`who`,' ',`recip`)\, `subject` FROM `%vpmail` WHERE `id` = '[sqlescape(%qi)]',,^),^(.+)\\^(.+)$,-1 r s))%qr,%:)),setr(x,ufun(%vb/beep))%qx*)),ufun(msg,no-good-replyers),switch(setr(t,elements(%qa,3,%qx)),?*,ufun(msg,these-players-bad,%qt)%r[ufun(tag)])[switchall(0,strlen(elements(setr(1,ufun(fun.checklocks,%qa,%0)),1,%qx)),ufun(msg,fail-locks-all,ufun(fun.format-names,elements(%q1,%qx,2),%0))[elements(%q1,3,%qx)],not(strmatch(%ql,?*%qx?*%qx*)),ufun(msg,fail-locks-some,ufun(fun.format-names,elements(%q1,2,%qx),%0))[elements(%q1,3,%qx)]%r[u(tag)],not(strlen(elements(%q1,1,%qx))),ufun(msg,reply-msg,ufun(fun.mail-start-sub,%0,ufun(msg,reply-subject,%qs),elements(%q1,1,%qx)),switch(%1,%0,,ufun(%vb/fun.format-name-noansi,%1)%b)[elements(%q0,3,|)]))])

@@ This just infinitely prepends "Re: ", which was the old behaviour with +mail/config re_subject
@@ &en`reply-subject %vc=Re: %0

@@ This does "Re: subj", then "Re (count): subj"
@@ &en`reply-subject %vc=localize(switch(%0,Re: *,Re (2): [after(%0,%b)],Re (*):*,if(isnum(setr(C,first(rest(%0,\(),\)))),Re ([add(%qC,1)]): [after(%0,:)],Re: %0),Re: %0))

@@ This does "Re: subj", "Re: Re: subj", then "Re (count): subj".
&en`reply-subject %vc=localize(if(regmatch(%0,^((?:Re: )+)(.*?)$,- 1 2),switch(words(%q1),1,Re: Re: %q2,Re \([add(words(%q1),1)]\): %q2),if(regmatch(%0,^Re \\((\[0-9\]+)\\): (.*)$,- 1 2),Re ([add(%q1,1)]): %q2,Re: %0)))

@@ @@@@@@@@@@@@@@@@@@@
@@ +FORWARD [@<alt> [<bb>] <range>=<address>
&cmd.forward %va=$+forward *=*: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.forward,%0,%1)]

&fun.forward %vb=ufun(fun.parseargs,%0)[switch(ufun(fun.isalt,%:,%qa,a),-1,ufun(msg,no-such-player,%qa),0,ufun(msg,not-an-alt,%qa),switch(0,ufun(fun.can-mail-guest,%:),ufun(msg,no-guest-mail),not(ufun(fun.writing-mail,%:)),ufun(msg,already-writing),ufun(fun.can-mail-banned,%:),ufun(msg,banned-from-mailing),strlen(%qc),ufun(msg,forward-which),strlen(%qb),ufun(fun.forward-sub,%:,%qa,%qc,%1),strlen(setr(1,ufun(fun.is-bb,%qb))),ufun(msg,no-such-bb,%qb),ufun(fun.can-read-bb,%qa,%q1),ufun(msg,cant-read-bb,%q1),ufun(fun.forward-sub,%:,%q1,%qc,%1)))]


@@ Player %0 wants to foward message range %2 from the inbox of %1 to the address %3.
&fun.forward-sub %vb=switch(0,first(setr(0,ufun(fun.range,%1,%0,%2)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),lte(words(setr(i,elements(%q0,2,|))),get(%vb/config`max_includes`value)),ufun(msg,too-many-includes,get(%vb/config`max_includes`value)),not(strmatch(setr(a,ufun(fun.parseaddr,%3,%:)),setr(x,ufun(%vb/beep))%qx*)),ufun(msg,no-good-players),switch(elements(%qa,3,%qx),?*,ufun(msg,these-players-bad,elements(%qa,3,%qx))%r[ufun(tag)])[switchall(0,strlen(elements(setr(1,ulocal(fun.checklocks,%qa,%0)),1,%qx)),ufun(msg,fail-locks-all,ufun(fun.format-names,elements(%q1,2,%qx),%0))[elements(%q1,3,%qx)],not(strmatch(%q1,?*%qx?*%qx*)),ufun(msg,fail-locks-some,ufun(fun.format-names,elements(%q1,2,%qx),%0))[elements(%q1,3,%qx)]%r[u(tag)],not(strlen(elements(%q1,1,%qx))),ufun(msg,forward-msg,ufun(fun.mail-start-sub,%0,ufun(msg,forward-subject,words(%qi),edit(sql(SELECT `subject` FROM `%vpmail` WHERE `id` IN\([iter(elements(%q0,2,|),'[sqlescape(##)]',,\,)]\),|),|,\,%b)),elements(%q1,1,%qx)),words(elements(%q0,2,|)))[ufun(fun.attach,%0,elements(%q0,2,|))])])

@@ %0 = author, %1 = subject, %2 = recip

@@ FUN.ATTACH - for player %0, attach the messages with ids %1 into his current mail
&fun.attach %vb=sql(UPDATE `%vpmail` SET `forwards` = '[sqlescape(|[setunion(edit(%1,%b,|),squish(sql(SELECT `forwards` FROM `%vpmail` WHERE `who` = '[sqlescape(%0)]' AND `sent` = '0'),|),|)]|)]' WHERE `who` = '[sqlescape(%0)]' AND `sent` = '0')

@@ @@@@@@@@@@@@@@@@@@@
@@ +INCLUDE [@<alt>] [<bb>] <range>
@@ +INCLUDE/REMOVE <id>
&cmd.include %va=$^\+include(/r(?\:e(?\:m(?\:o(?\:ve?)?)?)?)?)? (.+)$: @nspemit/silent %#=ufun(%vb/tag)[if(%1,ufun(%vb/fun.include-remove,%2),ufun(%vb/fun.include,%2))]
@set %va/cmd.include=regexp

@@ Player %: typed '+include %0'
&fun.include %vb=switch(0,ufun(%vb/fun.writing-mail,%:),ufun(msg,not-writing),ufun(fun.parseargs,%0)[strlen(%qc)],ufun(msg,which,include),switch(ufun(%vb/fun.isalt,%:,%qa,a),-1,ufun(msg,no-such-player,%qa),0,ufun(msg,not-an-alt,%qa),switch(0,strlen(%qb),ufun(fun.include-sub,%:,%qa,%qc),strlen(setr(1,ufun(fun.is-bb,%qb))),ufun(msg,no-such-bb,%qb),ufun(fun.can-read-bb,%qa,%q1),ufun(msg,cant-read-bb,%q1),ufun(fun.include-sub,%:,%q1,%qc))))

@@ Player %0 wants to include message range %2 from inbox of %1.
&fun.include-sub %vb=switch(0,first(setr(0,ufun(fun.range,%1,%0,%2)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),setq(n,squish(sql(SELECT `forwards` FROM `%vpmail` WHERE `who` = '[sqlescape(%0)]' AND `sent` = '0'),|))[lte(words(setunion(setr(i,elements(%q0,2,|)),edit(%qn,|,%b))),get(%vb/config`max_includes`value))],ufun(msg,too-many-includes,get(%vb/config`max_includes`value)),ufun(fun.attach,%0,%qi))[ufun(msg,attach,words(%qi))]

@@ Player %: typed '+include/remove %0'
&fun.include-remove %vb=switch(0,ufun(%vb/fun.writing-mail,%:),ufun(msg,not-writing),words(setr(0,setinter(edit(setr(i,squish(sql(SELECT `forwards` FROM `%vpmail` WHERE `who` = '[sqlescape(%:)]' AND `sent` = '0'),|)),|,%b),%0))),ufun(msg,no-such-include,%0),ufun(fun.detach,%:,%q0))

@@ Remove attachment id %1 from %0's current mail
&fun.detach %vb=null(sql(UPDATE `%vpmail` SET `forwards` = '[sqlescape(|[setdiff(squish(sql(SELECT `forwards` FROM `%vpmail` WHERE `who` = '[sqlescape(%0)]' AND `sent`='0'),|),edit(%1,%b,|),|)]|)]' WHERE `who` = '[sqlescape(%0)]' AND `sent` = '0'))[ufun(msg,include-removed,%1)]

@@ @@@@@@@@@@@@@@@@@@@
@@ +INCLUDES
&cmd.includes %va=$+includes: @nspemit/silent %#=ufun(%vb/tag)[switch(0,ufun(%vb/fun.writing-mail,%:),ufun(%vb/msg,not-writing),words(setr(0,squish(sql(SELECT `forwards` FROM `%vpmail` WHERE `who` = '[sqlescape(%:)]' AND `sent` = '0'),|)),|),ufun(%vb/msg,no-includes),ufun(%vb/msg,these-includes,sort(%q0,n,|,%b)))]

@@ @@@@@@@@@@@@@@@@@@@
@@ +SUBJECT <subject>
&cmd.subject %va=$^\+subject(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)? (.+)$: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.subject,%1)]
@set %va/cmd.subject=regexp

&fun.subject %vb=switch(0,ufun(%vb/fun.writing-mail,%:),ufun(msg,not-writing),sql(UPDATE `%vpmail` SET `subject` = '[sqlescape(ufun(fun.format-subject,%0))]' WHERE `who` = '[sqlescape(%:)]' AND `sent` = '0')[ufun(msg,subject-updated)])

@@ @@@@@@@@@@@@@@@@@@@
@@ -<msg>
@@ +WRITE[/nospace][/noeval] <msg>
&cmd.write-short %va=$^-([^-]|(?\:\s|\S){2,})$: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.write,%1,0)]
@set %va/cmd.write-short=regexp
&cmd.write %va=$^\+write((?\:/nos(?\:p(?\:a(?\:ce?)?)?)?)?(?\:/noe(?\:v(?\:al?)?)?)?|(?\:/nos(?\:p(?\:a(?\:ce?)?)?)?)?(?\:/noe(?\:v(?\:al?)?)?)?)? ((?\:\s|\S)+)$: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.write,%2,strmatch(%1,*/nos*))]
@set %va/cmd.write=regexp

@@ %: wants to write %0. If %1, don't put a space before it.
&fun.write %vb=switch(0,ufun(fun.writing-mail,%:),ufun(msg,not-writing),ufun(fun.store-undo,%:)[sql(UPDATE `%vpmail` SET `body` = CONCAT(`body`,[if(%1,,'%b'\,)]'[sqlescape(edit(%0,ufun(%vb/beep),))]') WHERE `who` = '[sqlescape(%:)]' AND `sent` = '0')][ufun(msg,write)])

&fun.store-undo %vb=null(sql(REPLACE INTO `%vpundo`\(`who`\,`data`\) VALUES\('[sqlescape(%0)]'\,'[sqlescape(sql(SELECT `body` FROM `%vpmail` WHERE `who` = '[sqlescape(%0)]' AND `sent` = '0'))]'\)))

@@ @@@@@@@@@@@@@@@@@@@
@@ +UNDO
&cmd.undo %va=$+undo: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.undo)]

&fun.undo %vb=switch(0,ufun(fun.writing-mail,%:),ufun(msg,not-writing),setq(0,sql(SELECT `data` FROM `%vpundo` WHERE `who` = '[sqlescape(%:)]'))[ufun(fun.store-undo,%:)][sql(UPDATE `%vpmail` SET `body` = '[sqlescape(%q0)]' WHERE `who` = '[sqlescape(%:)]' AND `sent` = '0')][ufun(msg,undo)])

@@ @@@@@@@@@@@@@@@@@@@
@@ --
@@ +SEND[/nosig][/loud]
@@   If /nosig, don't append signature. If /loud, notify all recipients that the mail is sent, even if %: is dark.
&cmd.send-short %va=$--: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.send,0,0)]

&cmd.send %va=$^\+send((?\:/n(?\:o(?\:s(?\:ig?)?)?)?)?(?\:/l(?\:o(?\:ud?)?)?)?|(?\:/l(?\:o(?\:ud?)?)?)?(?\:/n(?\:o(?\:s(?\:ig?)?)?)?)?)?$: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.send,strmatch(%1,*/n*),strmatch(%1,*/l*))]
@set %va/cmd.send=regexp


@@ Player %: wants to send his mail. If %0, don't add a sig. If %1, do it loud even if he's dark.
&fun.send %vb=switch(0,ufun(fun.writing-mail,%:),ufun(msg,not-writing),ufun(fun.can-mail-banned,%:),ufun(msg,banned-from-mailing),null(setq(0,sql(SELECT `id`\,`recip`\,`subject` FROM `%vpmail` WHERE `who` = '[sqlescape(%:)]' AND `sent` = '0',%b,^))[sql(UPDATE `%vpmail` SET `sent` = '1'\, `sig` = '[if(%0,,sqlescape(ufun(fun.mailsig,%:)))]'\, `date` = '[sqlescape(secs())]' WHERE `who` = '[sqlescape(%:)]' AND `sent` = '0')][sql(DELETE FROM `%vpundo` WHERE `who` = '[sqlescape(%:)]')][ulocal(fun.send-sub,%:,%#,ufun(fun.propername-enactor),nand(hidden(%:),not(%1)),sqlescape(elements(%q0,1,^)),elements(%q0,2,^),elements(%q0,3,^))])[ufun(msg,sent,elements(%q0,1,^))])

@@ %0 = objid, %1 = dbref, %2 = name, %3 = announce?, %4 = mail-id, %5 = addr, %6 = subject
&fun.send-sub %vb=null(if(strlen(graball(%5,#*:*)),sql(INSERT INTO `%vpinbox`\(`id`\,`who`\,`status`\) VALUES[iter(graball(%5,#*:*),\('%4'\,'[sqlescape(##)]'\,'n'\),,\,)]))[if(strlen(regraballi(%5,^(?!#.*:.*).*$)),sql(INSERT INTO `%vpbbinbox`\(`id`\,`bbcode`\,`readers`\) VALUES[iter(regraballi(%5,^(?!#.*:.*).*$),\('%4'\,'##'\,'||'\),,\,)]))])[switch(setr(0,if(%3,iter(graball(%5,#*:*),'[sqlescape(##)]',,\,),edit(squish(iter(graball(%5,#*:*),if(member(lwho(##),%1),'[sqlescape(##)']),,|),|),|,\,))),,,setq(0,sql(SELECT `%vpinbox`.`who`\,`%vpinbox`.`id` FROM `%vpinbox` INNER JOIN `%vpmail` ON `%vpinbox`.`id`=`%vpmail`.`id` WHERE `%vpinbox`.`who` IN \(%q0\) ORDER BY `%vpmail`.`date`,%b,|))[iter(setinter(regeditall(%q0,(:\\S+),%b),lwho()),nspemit(##,ufun(tag)[ufun(msg,new-mail[if(andlflags(##,nospoof paranoid),-nospoof)],%1,%2,match(graball(%q0,objid(##)|*),*|%4),%6)]))])][setq(s,if(%3,1,member\(lwho\(##\)\,%1\)))][setq(0,sql(SELECT `%vpbbinbox`.`bbcode`\,`%vpbbinbox`.`id` FROM `%vpbbinbox` INNER JOIN `%vpmail` ON `%vpbbinbox`.`id`=`%vpmail`.`id` ORDER BY `%vpmail`.`date`,|,^))][iter(regraballi(%5,^(?!#.*:.*).*$),nspemit(iter(filterbool(#lambda/%qs,lwho()),if(ufun(%vb/fun.can-notify-bb,%i0,##),%i0)),ufun(tag)[ufun(msg,new-bb-posting,ufun(fun.format-names-bb,%0,%:,setr(b,ufun(fun.bbnum-to-name,##))),%qb,match(graball(%q0,##^*,|),*^%4,|),%6)]))]

&fun.mailsig %vb=localize(switch(setr(0,left(stripansi(ufun(%0/mailsignature)),150)),,,%r%q0))

@@ #abc

@@ @@@@@@@@@@@@@@@@@@@
@@ +PROOF[/examine]
@@ +DRAFT
&cmd.proof %va=$^\+proof(/e(?\:x(?\:a(?\:m(?\:i(?\:ne?)?)?)?)?)?)?$: @nspemit/silent %#=ufun(%vb/fun.proof,%:,t(strlen(%1)))

@@ %0 = objid (%:), %1 = /examine?
&fun.proof %vb=switch(0,ufun(%vb/fun.writing-mail,%0),ufun(%vb/tag)[ufun(%vb/msg,not-writing)],setq(0,sql(SELECT `id`\,`date`\,`subject`\,`recip`\,CONCAT(`body`\,`sig`)\,`forwards` FROM `%vpmail` WHERE `who` = '[sqlescape(%0)]' AND `sent` = '0',%b,setr(x,ufun(%vb/beep))))[ufun(%vb/fun.format-message,-1,,elements(%q0,1,%qx),if(%1,e%b)p,%:,elements(%q0,2,%qx),elements(%q0,3,%qx),elements(%q0,4,%qx),elements(%q0,5,%qx),if(squish(elements(%q0,6,%qx),|),sql(SELECT `id`\,`who`\,`date`\,CONCAT(`body`\,`sig`) FROM `%vpmail` WHERE `id` IN\([iter(squish(elements(%q0,6,%qx),|),'[sqlescape(##)]',|,\,)]\),%qx,^)))])
@set %va/cmd.proof=regexp

&cmd.draft %va=$+draft: @nspemit/silent %#=ufun(%vb/fun.proof,%:,1)

@@ @@@@@@@@@@@@@@@@@@@
@@ +EDIT <old>/<new>
@@ +EDIT/delim <delim> <old><delim><new>
@@ +EDIT/REGEXP[all][i] <delim> <old><delim><new>
&cmd.edit %va=$^\+edit(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)?((?\:/r(?\:e(?\:g(?\:e(?\:x(?\:p(?\:a(?\:l(?\:li?)?)?|i)?)?)?)?)?)?)?|(?\:/d(?\:e(?\:l(?\:im?)?)?)?)?)?(?\:/n(?\:o(?\:e(?\:v(?\:al?)?)?)?)?)? (.+)$: @nspemit/silent %#=ufun(%vb/tag)[switch(%1,/r*,ufun(%vb/fun.edit,grab(regedit regediti regeditall regeditalli,edit(%1,x,d,p,it,/,)),before(rest(%2),first(%2)),after(rest(%2),first(%2))),/d*,ufun(%vb/fun.edit,edit,before(rest(%2),first(%2)),after(rest(%2),first(%2))),ufun(%vb/fun.edit,edit,first(%2,/),rest(%2,/)))]

@set %va/cmd.edit=regexp

&fun.edit %vb=switch(0,ufun(fun.writing-mail,%:),ufun(msg,not-writing),setq(0,sql(SELECT `id`\,`date`\,`subject`\,`recip`\,`body` FROM `%vpmail` WHERE `who` = '%:' AND `sent` = '0',%b,setr(x,ufun(%vb/beep))))[ufun(fun.store-undo,%:)][sql(UPDATE `%vpmail` SET `body` = '[sqlescape(localize(switch(%0,edit,edit(elements(%q0,5,%qx),%1,%2),[%0(elements(%q0,5,%qx),%1,setq(0,$0,1,$1,2,$2,3,$3,4,$4,5,$5,6,$6,7,$7,8,$8,9,$9)[regeditall(%2,\\$(\\d),r($1))])])))]' WHERE `who` = '%:' AND `sent` = '0')][ufun(msg,edit)]%r[ufun(fun.format-message,-1,,elements(%q0,1,%qx),p,%:,elements(%q0,2,%qx),elements(%q0,3,%qx),elements(%q0,4,%qx),switch(%0,edit,edit(elements(%q0,5,%qx),%1,ansi(h,%2)),localize([%0(elements(%q0,5,%qx),%1,setq(0,$0,1,$1,2,$2,3,$3,4,$4,5,$5,6,$6,7,$7,8,$8,9,$9)[ansi(h,regeditall(%2,\\$(\\d),r($1)))])])))])

@@ @@@@@@@@@@@@@@@@@@@
@@ +UNREAD [@<alt>] [<bb>] <range>
&cmd.unread %va=$+unread *: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.unread,%0,r,n)]

@@ Take messages (args: %0) which are marked as %1 and change to %2. Used by +unread and +read/mark
&fun.unread %vb=ufun(fun.parseargs,%0)[switch(ufun(fun.isalt,%:,%qa,a),-1,ufun(msg,no-such-player,%qa),0,ufun(msg,not-an-alt,%qa),switch(0,strlen(%qb),ufun(fun.unread-player,%qa,%:,%qc,%1,%2),strlen(setr(1,ufun(fun.is-bb,%qb))),ufun(msg,no-such-bb,%qb),ufun(fun.can-read-bb,%qa,%q1),ufun(msg,cant-read-bb,%q1),ufun(fun.unread-bb,%qb,%qa,%qc,%1,%2)))]

@@ %0 = whose inbox? %1 = who's typing? %2 = range, %3 = start status, %4 = status to change to
&fun.unread-player %vb=switch(0,first(setr(0,ufun(fun.range,%0,%1,%2)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),null(sql(UPDATE `%vpinbox` SET `status` = '%4' WHERE `who` = '%0' AND `status` = '%3' AND `id` IN([iter(elements(%q0,2,|),'##',,\,)])))[ufun(msg,marked-as-new,elements(ufun(fun.range,%0,%1,mark=n),3,|))])


@@ %0 = bb name, %1 = player reading, %2 = range, %3 = start status, %4 = status to change to.
&fun.unread-bb %vb=switch(0,first(setr(0,ufun(fun.range,%0,%1,%2)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),setq(1,ufun(fun.bbname-to-num,%0))[null(iter(sql(SELECT `id`\,`readers` FROM `%vpbbinbox` WHERE `bbcode` = '%q1' AND `readers` [switch(%3,n,NOT)] LIKE '[get(%vb/config`sql_wildcard`value)]|%1|[get(%vb/config`sql_wildcard`value)]' AND `id` IN([iter(elements(%q0,2,|),'##',,\,)])  ,_,^),sql(UPDATE `%vpbbinbox` SET `readers` = '|[set[switch(%3,r,diff,union)](squish(elements(##,2,^),|),%1,|)]|' WHERE `id` = '[elements(##,1,^)]' AND `bbcode` = '%q1'),_,))][setq(3,sql(SELECT `%vpbbinbox`.`id` FROM `%vpbbinbox` INNER JOIN `%vpmail` ON `%vpmail`.`id`=`%vpbbinbox`.`id` WHERE `%vpbbinbox`.`bbcode`='%q1' ORDER BY `%vpmail`.`date`))][ufun(msg,marked-as-new,sort(iter(sql(SELECT `id` FROM `%vpbbinbox` WHERE `bbcode` = '%q1' AND `readers` NOT LIKE '[get(%vb/config`sql_wildcard`value)]|%1|[get(%vb/config`sql_wildcard`value)]'),member(%q3,##)),n))])

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBCATCHUP <bb>
@@ Alias for +read/mark <bb>
&cmd.bbcatchup %va=$+bbcatchup *: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.unread,bb:%0,n,r)]

@@ @@@@@@@@@@@@@@@@@@@
@@ +BBREAD [<bb>[/<message range>]] #abc123
&cmd.bbread %va=$+bbread */*: @nspemit/silent %#=ufun(%vb/fun.read,bb:%0 [switch(%1,u,mark=new,%1)],0,ufun(%vb/tag))
&cmd.bbread %va=$^\+bbread\s*(?\: (.+?)(/(.*))?)?$: @nspemit/silent %#=switch(,%1,ufun(%vb/fun.bblist-all,%:),%2,ufun(%vb/fun.skim,bb:%1),ufun(%vb/fun.read,bb:%1 [switch(%3,u,mark=new,%3)],0,ufun(%vb/tag)))
@set %va/cmd.bbread=regexp

@@ @@@@@@@@@@@@@@@@@@@
@@ +READ[/examine] [@<alt>] [<bb>] [<range>]
@@ +READ/SENT[/examine] [@<alt>] <id>
@@ +READ/MARK [@<alt> [<bb>] [<range>]
&cmd.read %va=$^\+read((?\:/m(?\:a(?\:rk?)?)?)?|(?\:(?\:/e(?\:x(?\:a(?\:m(?\:i(?\:ne?)?)?)?)?)?)?(?\:/s(?\:e(?\:nt?)?)?)?|(?\:/s(?\:e(?\:nt?)?)?)?(?\:/e(?\:x(?\:a(?\:m(?\:i(?\:ne?)?)?)?)?)?)?))?(?\: (.+))?$: @nspemit/silent %#=switch(%1,*/s*,ufun(%vb/fun.read-sent,%2,strmatch(%1,*/e*),ufun(%vb/tag)),*/m*,ufun(%vb/tag)[ufun(%vb/fun.unread,%2,n,r)],ufun(%vb/fun.read,%2,strmatch(%1,*/e*),ufun(%vb/tag)))
@set %va/cmd.read=regexp


&fun.read-mark %vb=ufun(fun.parseargs,%0)[ufun(tag)][switch(ufun(fun.isalt,%:,%qa,a),-1,ufun(msg,no-such-player,%qa),0,ufun(msg,not-an-alt,%qa),switch(0,first(setr(0,ufun(fun.range,%qa,%:,%qc)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),sql(UPDATE `%vpinbox` SET `status` = 'r' WHERE `id` IN([iter(elements(%q0,2,|),'##',,\,)]) AND `who` = '%qa' AND `status` = 'n')[setq(2,sql(SELECT `%vpinbox`.`id` FROM `%vpinbox` INNER JOIN `%vpmail` ON `%vpmail`.`id` = `%vpinbox`.`id` WHERE `%vpinbox`.`who` = '%qa' ORDER BY `%vpmail`.`date`))][ufun(msg,marked-as-new,sort(iter(sql(SELECT `id` FROM `%vpinbox` WHERE `who` = '%qa' AND `status` = 'n'),member(%q2,##)),n))]))]

&fun.read-sent %vb=ufun(fun.parseargs-nobb,%0)[switch(ufun(fun.isalt,%:,%qa,a),-1,%2[ufun(msg,no-such-player,%qa)],0,%2[ufun(msg,not-an-alt,%qa)],switch(0,strlen(%qc),%2[ufun(msg,read-which)],strlen(setr(0,sql(SELECT `id`\,CONCAT(`who`\,' '\,`recip`)\, `sent` FROM `%vpmail` WHERE `id` = '[sqlescape(%qc)]',%b,setr(x,ufun(%vb/beep))))),%2[ufun(msg,no-such-id)],cor(setinter(elements(%q0,2,%qx),%qa),elock(%vb/see_all,%qa)),%2[ufun(msg,cant-read-sent)],elements(%q0,3,%qx),%2[ufun(msg,read-sent-unsent)],setq(1,sql(SELECT `id`\,`who`\,`date`\,`subject`\,`recip`\,CONCAT(`body`\,`sig`)\,`forwards` FROM `%vpmail` WHERE `id` = '[sqlescape(%qc)]',%b,%qx))[ulocal(fun.format-message,-1,,%qc,if(%1,e%b)s,elements(%q1,2,%qx),elements(%q1,3,%qx),elements(%q1,4,%qx),elements(%q1,5,%qx),elements(%q1,6,%qx),if(squish(elements(%q1,7,%qx),|),sql(SELECT `id`\,`who`\,`date`\,CONCAT(`body`\,`sig`) FROM `%vpmail` WHERE `id` IN([iter(squish(elements(%q1,7,%qx),|),'[sqlescape(##)]',|,\,)]),%qx,^)))]))]

@@ Args passed to fun.read: %0 = args to +read, %1 = /examine?, %2 = [+mail] tag
&fun.read %vb=ufun(fun.parseargs,%0)[switch(ufun(fun.isalt,%:,%qa,a),-1,%2[ufun(msg,no-such-player,%qa)],0,%2[ufun(msg,not-an-alt,%qa)],switch(0,strlen(%qc),%2[ufun(msg,read-which)],strlen(%qb),ufun(fun.read-sub,%qa,%qc,%1,%2),strlen(setr(1,ufun(fun.is-bb,%qb))),%2[ufun(msg,no-such-bb,%qb)],ufun(fun.can-read-bb,%qa,%q1),%2[ufun(msg,cant-read-bb,%q1)],ufun(fun.read-sub,%q1,%qc,%1,%2,%qa)))]

@@ Player %: wants to read msg range %1 from %0. If %2, noeval. %3 is the +mail tag. %4 is the alt with read perms
&fun.read-sub %vb=switch(0,first(setr(0,ufun(fun.range,%0,%:,%1)),|),%3[ufun(msg,elements(%q0,2,|),elements(%q0,3,|))],lte(words(setr(i,elements(%q0,2,|))),get(%vb/config`max_reads`value)),%3[ufun(msg,too-many-reads,get(%vb/config`max_reads`value))],setq(x,ufun(%vb/beep))[setq(m,elements(%q0,3,|))][iter(%qi,setq(1,switch(%0,#*:*,sql(SELECT `%vpmail`.`id`\,`%vpmail`.`who`\,`%vpmail`.`date`\,`%vpmail`.`subject`\,`%vpmail`.`recip`\,CONCAT(`%vpmail`.`body`\,`%vpmail`.`sig`)\,`%vpmail`.`forwards`\,`%vpinbox`.`status` FROM `%vpmail` INNER JOIN `%vpinbox` ON `%vpinbox`.`id` = `%vpmail`.`id` WHERE `%vpmail`.`id` = '[sqlescape(%i0)]' AND `%vpinbox`.`who`='[sqlescape(%0)]',%b,%qx),sql(SELECT `%vpmail`.`id`\,`%vpmail`.`who`\,`%vpmail`.`date`\,`%vpmail`.`subject`\,`%vpmail`.`recip`\,CONCAT(`%vpmail`.`body`\,`%vpmail`.`sig`)\,`%vpmail`.`forwards`\,CASE WHEN INSTR(`%vpbbinbox`.`readers`,'[sqlescape(|%4|)]') > 0 THEN 'r' ELSE 'n' END FROM `%vpmail` INNER JOIN `%vpbbinbox` ON `%vpbbinbox`.`id`=`%vpmail`.`id` WHERE `%vpmail`.`id` = '[sqlescape(%i0)]' AND `%vpbbinbox`.`bbcode`='[sqlescape(ufun(fun.bbname-to-num,%0))]',%b,%qx)))[ulocal(fun.format-message,elements(%qm,#@),switch(%0,%:,,%0),%i0,setunion(elements(%q1,8,%qx),if(%2,e)),elements(%q1,2,%qx),elements(%q1,3,%qx),elements(%q1,4,%qx),elements(%q1,5,%qx),elements(%q1,6,%qx),if(squish(elements(%q1,7,%qx),|),sql(SELECT `id`\,`who`\,`date`\,CONCAT(`body`\,`sig`) FROM `%vpmail` WHERE `id` IN([iter(squish(elements(%q1,7,%qx),|),'[sqlescape(%i0)]',|,\,)]),%qx,^)))],,%r)][null(switch(%0,#*:*,sql(UPDATE `%vpinbox` SET `status`='r' WHERE `who` = '[sqlescape(%0)]' AND `id` IN([iter(%qi,'[sqlescape(%i0)]',,\,)]) AND `status` = 'n'),sql(UPDATE `%vpbbinbox` SET `readers` = CONCAT('|',TRIM(BOTH '|' FROM CONCAT(TRIM(BOTH '|' FROM `readers`),'[sqlescape(|%qa)]')),'|') WHERE `bbcode` = '[sqlescape(ufun(fun.bbname-to-num,%0))]' AND `id` IN([iter(%qi,'[sqlescape(%i0)]',,\,)]) AND `readers` NOT LIKE '[sqlescape(get(%vb/config`sql_wildcard`value)|%4|[get(%vb/config`sql_wildcard`value)])]')))])

@@ [null(sql(UPDATE `inbox` SET `status`='r' WHERE `who` = '[sqlescape(%qa)]' AND `id` IN([iter(%qi,'[sqlescape(##)]',,\,)]) AND `status` = 'n'))]


@@ @@@@@@@@@@@@@@@@@@@
@@ +DELETE[/force] <range>
&cmd.delete %va=$^\+delete(/f(?\:o(?\:r(?\:ce?)?)?)?)? (.+): @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.delete,%2,t(strlen(%1)))]
@set %va/cmd.delete=regexp
&cmd.expunge %va=$+expunge *: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.delete,%0,1)]

@@ %0 = <bb> and <range>, %1 = /force?
&fun.delete %vb=ufun(fun.parseargs-noalt,%0)[switch(0,not(cand(not(strlen(%qc)),%1)),ufun(msg,expunge-norange),strlen(%qb),ufun(fun.delete-personal,%:,%qc,%1),%1,ufun(msg,delete-bb-noforce),ufun(fun.delete-bb,%qb,%:,%qc,%1))]

&en`expunge-norange %vc=You must give a message range to +EXPUNGE. To delete all messages, use the message range '-'

@@ %0 = user, %1 = range, %2 = /force?
&fun.delete-personal %vb=switch(0,first(setr(0,ufun(fun.range,%0,%0,%1)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),if(cand(not(%2)[setq(1,iter(elements(%q0,2,|),'##',,\,))],words(sql(SELECT `status` FROM `%vpinbox` WHERE `who` = '%0' AND `status` = 'n' AND `id` IN(%q1)))),ufun(msg,delete-new)%r[u(tag)])[sql(UPDATE `%vpinbox` SET `status` = 'd' WHERE `who` = '%0' [if(%2,,AND `status` != 'n')] AND `id` IN(%q1))][setq(2,elements(ufun(fun.range,%0,%0),2,|))][ufun(msg,marked-as-del,sort(iter(sql(SELECT `id` FROM `%vpinbox` WHERE `status` = 'd' AND `who` = '%0'),member(%q2,%i0)),n))])

@@ %0 = bb, %1 = user, %2 = range, %3 = /force? (always 1)
&fun.delete-bb %vb=switch(0,strlen(setr(0,ufun(fun.is-bb,%0))),ufun(msg,no-such-bb,%0),cor(orflags(%1,Wr),ufun(fun.is-bb-admin,%1,%q0)),ufun(msg,permission-denied),switch(0,first(setr(1,ufun(fun.range,%q0,%1,%2)),|),ufun(msg,elements(%q1,2,|),elements(%q1,3,|)),sql(DELETE FROM `%vpbbinbox` WHERE `id` IN([iter(elements(%q1,2,|),'%i0',,\,)]) AND `bbcode` = '[ufun(fun.bbname-to-num,%q0)]')[ufun(msg,deleted-bb,%q0)]))

@@ %0 = range, %1 = /force?
@@ &fun.deleteOLD %vb=switch(0,first(setr(0,ufun(fun.range,%:,%:,%0)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),if(cand(not(%1)[setq(1,iter(elements(%q0,2,|),'##',,\,))],words(sql(SELECT `status` FROM `%vpinbox` WHERE `who` = '%:' AND `status` = 'n' AND `id` IN(%q1)))),ufun(msg,delete-new)%r[u(tag)])[sql(UPDATE `%vpinbox` SET `status` = 'd' WHERE `who` = '%:' [if(%1,,AND `status` != 'n')] AND `id` IN(%q1))][setq(2,elements(ufun(fun.range,%:,%:),2,|))][ufun(msg,marked-as-del,sort(iter(sql(SELECT `id` FROM `%vpinbox` WHERE `status` = 'd' AND `who` = '%:'),member(%q2,##)),n))])


@@ @@@@@@@@@@@@@@@@@@@
@@ +SKIM [@<alt>] [<bb>] [<range>]
&cmd.skim %va=$+skim*: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.skim,squish(%0))]

&fun.skim %vb=ufun(fun.parseargs,%0)[switch(ufun(fun.isalt,%:,%qa,a,1),-1,ufun(msg,no-such-player,%qa),0,ufun(msg,not-an-alt,%qa),switch(0,strlen(%qb),ufun(fun.skim-player,%qa,%:,%qc),strlen(setr(1,ufun(%vb/fun.is-bb,%qb))),ufun(msg,no-such-bb,%qb),ufun(fun.can-read-bb,%qa,%q1),ufun(msg,cant-read-bb,%q1),ufun(fun.skim-bb,%q1,%qa,%qc)))]

&fun.skim-player %vb=switch(0,first(setr(0,ufun(fun.range,%0,%1,%2)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),ufun(fun.skim-player-sub,%0,%1,elements(%q0,2,|),elements(%q0,3,|)))

@@ %0 = inbox owner, %1 = player typing, %2 = list of msg IDs, %3 = positions in box
&fun.skim-player-sub %vb=ufun(fun.mail-check-info,%0,%1)%r[repeat(-,78)]%r[setq(0,%0,1,%1,2,%2,3,%3)][mapsql(%!/fun.skim-player-sub-sub,SELECT `%vpmail`.`id`\,`%vpinbox`.`status`\,`%vpmail`.`who`\, `%vpmail`.`date`\,`%vpmail`.`subject` FROM `%vpmail` INNER JOIN `%vpinbox` ON `%vpinbox`.`id` = `%vpmail`.`id` WHERE `%vpmail`.`id` IN([iter(%2,'##',,\,)]) AND `%vpinbox`.`who` = '%0' ORDER BY `%vpmail`.`date`,%r)]%r[repeat(-,78)]%r+Delete mail you're done with!%b%bSee HELP POP3 to download it to your computer!

&fun.skim-player-sub-sub %vb=left(<[switch(%2,n,N,d,D,%b)]>[rjust(elements(%q3,%0),4)]. [ljust(left(ufun(fun.format-names,%3,%q1),17),18)] [timefmt($a $b $d $Y,%4)]%b%b-%b%b%5,78)

@@ %0 = BB, %1 = reader, %2 = range
&fun.skim-bb %vb=switch(0,first(setr(0,ufun(fun.range,%0,%1,%2)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),ufun(fun.skim-bb-sub,%0,%1,elements(%q0,2,|),elements(%q0,3,|)))

@@ %0 = bb, %1 = reader, %2 = msg ids, %3 = positions in inbox
&fun.skim-bb-sub %vb=ufun(fun.mail-check-info,%0,%1)%r[ufun(%vd/bb`header`%0)]%r[repeat(-,78)]%r[setq(0,%0,1,%1,2,%2,3,%3)][mapsql(%!/fun.skim-bb-sub-sub,SELECT `%vpmail`.`id`\, CASE WHEN INSTR(`%vpbbinbox`.`readers`,'|%1|') > 0 THEN ' ' ELSE 'n' END\, `%vpmail`.`who`\, `%vpmail`.`date`\, `%vpmail`.`subject` FROM `%vpmail` INNER JOIN `%vpbbinbox` ON `%vpbbinbox`.`id` = `%vpmail`.`id` WHERE `%vpmail`.`id` IN([iter(%2,'##',,\,)]) AND `%vpbbinbox`.`bbcode` = '[ufun(fun.bbname-to-num,%0)]' ORDER BY `%vpmail`.`date`,%r)]%r[repeat(-,78)]

&fun.skim-bb-sub-sub %vb=left(<[switch(%2,n,N,d,D,%b)]>[rjust(elements(%q3,%0),4)]. [ljust(left(ufun(fun.format-names-bb,%3,%q1,%q0),17),18)] [timefmt($a $b $d $Y,%4)]%b%B-%b%b%5,78)

@@ @@@@@@@@@@@@@@@@@@@
@@ +UNDELETE <range>
&cmd.undelete %va=$+undelete *: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.undelete,%0)]

&fun.undelete %vb=switch(0,first(setr(0,ufun(fun.range,%:,%:,%0)),|),ufun(msg,elements(%q0,2,|),elements(%q0,3,|)),sql(UPDATE `%vpinbox` SET `status` = 'r' WHERE `who` = '%:' AND `status` = 'd' AND `id` IN([iter(elements(%q0,2,|),'##',,\,)]))[setq(2,elements(ufun(fun.range,%:,%:),2,|))][ufun(msg,marked-as-del,sort(iter(sql(SELECT `id` FROM `%vpinbox` WHERE `status` = 'd' AND `who` = '%:'),member(%q2,##)),n))])

@@ @@@@@@@@@@@@@@@@@@@
@@ +DELETED
&cmd.deleted %va=$+deleted: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/msg,marked-as-del,elements(ufun(%vb/fun.range,%:,%:,mark=deleted),3,|))]

@@ @@@@@@@@@@@@@@@@@@@
@@ +CLEAR
&cmd.clear %va=$+clear: @nspemit/silent %#=ufun(%vb/tag)[sql(DELETE FROM `%vpinbox` WHERE `who` = '%:' AND `status` = 'd')][ufun(%vb/msg,clear)]

@@ @@@@@@@@@@@@@@@@@@@
@@ +TOSS
&cmd.toss %va=$+toss: @nspemit/silent %#=ufun(%vb/tag)[if(ufun(%vb/fun.writing-mail,%:),null(sql(DELETE FROM `%vpmail` WHERE `who` = '%:' AND `sent` = '0')[sql(DELETE FROM `%vpundo` WHERE `who` = '%:')])[ufun(%vb/msg,toss)],ufun(%vb/msg,not-writing))]

@@ @@@@@@@@@@@@@@@@@@@
@@ +ERASE[/all]
&cmd.erase %va=$^\+erase(/a(?\:ll?)?)?$: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.erase,t(%1))]
@set %va/cmd.erase=regexp

&fun.erase %vb=switch(0,ufun(%vb/fun.writing-mail,%:),ufun(msg,not-writing),ufun(fun.store-undo,%:)[sql(UPDATE `%vpmail` SET `body` = ''[if(%0,\, `subject` = '[sqlescape(ufun(fun.format-subject,))]'\, forwards='||')] WHERE `who` = '%:' AND `sent` = '0')][ufun(msg,erase[if(%0,-all)])])

@@ @@@@@@@@@@@@@@@@@@@
@@ +OUTBOX[/id] [@<alt>]
&cmd.outbox %va=$^\+outbox(/id?)?(.*)$: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.outbox,switch(%1,/i*,id,date),%2)]
@set %va/cmd.outbox=regexp

@@ %0 = 'id' or 'date', %1 = args (for alt)
&fun.outbox %vb=ufun(fun.parseargs,%1)[switch(ufun(%vb/fun.isalt,%:,%qa,a,1),-1,ufun(msg,no-such-player,%qa),0,ufun(msg,not-an-alt,%qa),switch(setr(0,sql(SELECT `id`\,`date`\,`subject`\,`recip` FROM `%vpmail` WHERE `who` = '%qa' AND `sent` = '1' ORDER BY `%0`,setr(x,u(beep)),^)),,ufun(msg,outbox-none),ufun(fun.outbox-sub,%q0,%qx)))]

&fun.outbox-sub %vb=ufun(msg,outbox-num,words(%0,%1))%r[repeat(=,78)]%r[ljust(ID Num,8)][ljust(Date,12)][ljust(Subject,27)]Address%r[repeat(-,78)]%r[iter(%0,left(ljust(rjust(elements(%i0,1,^),6),8)[ljust(timefmt($x,elements(%i0,2,^)),12)][ljust(left(elements(%i0,3,^),24),27)][ufun(fun.format-names,elements(%i0,4,^),%:)],78),%1,%r)]%r[repeat(=,78)]

@@ @@@@@@@@@@@@@@@@@@@
@@ +UNMAIL <id>
&cmd.unmail %va=$+unmail *: @nspemit/silent %#=ufun(%vb/tag)[ufun(%vb/fun.unmail,%0)]

&fun.unmail %vb=switch(0,not(ufun(%vb/fun.writing-mail,%:)),ufun(msg,unmail-already-writing),words(setr(0,sql(SELECT `id`\,`recip`\,`subject` FROM `%vpmail` WHERE `who` = '%:' AND `id` = '[sqlescape(%0)]',%b,^))),ufun(msg,unmail-bad),setq(1,elements(%q0,1,^))[setq(2,elements(%q0,2,^))][setq(3,elements(%q0,3,^))][setq(t,ufun(tag))][setq(r,squish(setunion(sql(SELECT `readers` FROM `%vpbbinbox` WHERE `id`='%q1',|,|),sql(SELECT `who` FROM `%vpinbox` WHERE `id`='%q1' AND `status`!='n',|,|),|),|))][null(iter(graball(%q2,#*:*),nspemit(##,%qt[ufun(msg,unmail-taken,ufun(fun.propername-enactor),member(sql(SELECT `%vpinbox`.`id` FROM `%vpinbox` INNER JOIN `%vpmail` ON `%vpinbox`.`id` = `%vpmail`.`id` WHERE `%vpinbox`.`who` = '##' ORDER BY `%vpmail`.`date`),%q1),%q3)])))][sql(DELETE FROM `%vpinbox` WHERE `id`='%q1')][sql(DELETE FROM `%vpbbinbox` WHERE `id`='%q1')][sql(UPDATE `%vpmail` SET `sent` = '0'\, `sig` = '' WHERE `id` = '%q1')][if(%qr,ufun(msg,unmail-readby,ufun(fun.format-names,stripansi(edit(%qr,|,%b)),%:))%r[u(tag)])][ufun(msg,unmail-done,%q1)])

@@ @@@@@@@@@@@@@@@@@@@
@@ SENDMAIL() function
@@ A ufun for sending mail in one quick go, functionally. Can only be used by those
@@ passing the %vb/sendmail @lock.
@@ ARGS: %0 = From, %1 = Address, %2 = Subject, %3 = Message, %4 = Don't announce?
@@ (ie, ufun(%vb/fun.sendmail,%#,BB:Public PLAYER:Fred #5 Foo,Hello!,Hello everyone!%r%rFoo!))
&fun.sendmail %vb=if(elock(%!/u:sendmail,%@),[setq(c,%@)][eval(%!,fun.sendmail-sub)],#-1 PERMISSION DENIED)
@set %vb/fun.sendmail=visual public

@@ %qc is passed from fun.sendmail, and is the real caller (%@) of the function
&fun.sendmail-sub %vb=localize(switch(0,comp(left(setr(1,ulocal(fun.parseaddr,%1,owner(%qC))),2),beep(2)),0,null(sql(INSERT INTO `%vpmail`(`who`,`date`,`subject`,`recip`,`body`,`sent`,`forwards`) VALUES('[setr(0,firstof(objid(pmatch(%0)),objid(pmatch(#1)),objid(pmatch(owner(%qc))),objid(owner(me))))]','[secs()]','[sqlescape(setr(S,ufun(fun.format-subject,%2)))]','[sqlescape(setr(1,elements(%q1,1 2,beep(),%b)))]','[sqlescape(edit(%3,ufun(%vb/beep),))]','1',''))[ufun(fun.send-sub,%q0,pmatch(%q0),ufun(fun.propername,%q0),not(%4),sql(SELECT last_insert_id()),%q1,%qs)])1))


@@ %0 = objid, %1 = dbref, %2 = name, %3 = announce?, %4 = mail-id, %5 = addr

@@ @@@@@@@@@@@@@@@@@@@
@@ POP3!
@@ All these attributes are for use by the MailBot character, for checking mail
@@ via POP3 (and eventually BBs via NNTP, too).
&pop3 %vb=switch(%@,%vz,ufun(do_pop3_%0,%1,%2,%3,%4,%6,%7,%8,%9),#-1 PERMISSION DENIED)
@set %vb/pop3=visual public
&do_pop3_getconfig %vb=v(config`%0`value)
&do_pop3_beep %vb=beep(2)
&do_pop3_delete %vb=sql(UPDATE `%vpinbox` SET `pop3` = '`' WHERE `who` = '%0' AND `id` IN\([iter(%1,'##',,\,)]\))Deleted.
&do_pop3_user %vb=objid(pmatch(%0))
&do_pop3_checkpass %vb=checkpass(%0,%1)
&do_pop3_people %vb=iter(%0,switch(##,#*:*,if(pmatch(##),name(##),Purged) <##@[get(%vb/config`mudname`value)]>,##@[get(%vb/config`mudname`value)]),,\,%b)


&do_pop3_list-messages %vb=sql(SELECT `%vpmail`.`id` FROM `%vpmail` INNER JOIN `%vpinbox` ON `%vpinbox`.`id` = `%vpmail`.`id` WHERE `%vpinbox`.`who` = '%0' AND `%vpinbox`.`pop3` = '0' ORDER BY `%vpmail`.`date`)

&do_pop3_get-message %vb=[setr(0,beep(5))] MESSAGE ID %0 STARTS %q0%r[stripansi(sql(SELECT `%vpmail`.`id`\,`%vpmail`.`who`\,`%vpmail`.`date`\,`%vpmail`.`subject`\,`%vpmail`.`recip`\,CONCAT(`%vpmail`.`body`\,'%r'\,`%vpmail`.`sig`) FROM `%vpmail` WHERE `%vpmail`.`id` = '%0',%b,%r))]%r%q0 MESSAGE ID %0 ENDS %q0


@@ ASK <id>---<type>---<arg1>---<arg2> 
&cmd.ask %vz=$MB!ask *---*---*---*: @wait me={think setr(0,ufun(%vb/pop3,beep)) START-%0 %q0%r[ulocal(%vb/pop3,%1,%2,%3)]%r%q0 END-%0 %q0 ; @notify me}

&cmd.getplayermail %vz=$MB!getPlayerMail */*: @wait me={think setr(0,ufun(%vb/pop3,beep)) START-%0 %q0 ; @dolist/notify [ufun(%vb/pop3,list-messages,%1)]=THINK [ufun(%vb/pop3,get-message,##)]} ; @wait me={think setr(0,ufun(%vb/pop3,beep)) END-%0 %q0 ; @notify me}

@startup %vz=@drain me ; @notify me
@restart %vz
@aconnect %vz=THINK MailBot> CONNECTED ; @wait 5={@trigger me/SETUP}
&setup %vz=@wait me={THINK MailBot> SETVAR mushname> [ufun(%vb/pop3,getconfig,mudname)] ; @notify me}
@listen %vb=SELF-TRIGGER-SETUP
@amhear %vb=@trigger %vz/setup

@@ @@@@@@@@@@@@@@@@@@@
@@ Finish off...

@set %va=!no_command
@dol %vb %vc %vd=@tel ##=%va
@tel %va=[config(master_room)]

THINK [ansi(h,CREATING MySQL TABLES...)]

@@ Create the MySQL tables.
@SQL CREATE TABLE `%vpinbox` ( `id` int(11) NOT NULL default '0', `who` char(20) NOT NULL default '', `status` char(1) NOT NULL default '', `pop3` smallint(6) NOT NULL default '0', PRIMARY KEY  (`id`,`who`)) TYPE=MyISAM

@SQL CREATE TABLE `%vpmail` (  `id` int(11) NOT NULL auto_increment,  `who` varchar(20) NOT NULL default '',  `date` bigint(20) NOT NULL default '0',  `subject` text NOT NULL,  `recip` text NOT NULL,  `body` longtext NOT NULL,  `sent` tinyint(4) NOT NULL default '0',  `sig` text NOT NULL,  `forwards` text NOT NULL,  PRIMARY KEY  (`id`)) TYPE=MyISAM

@SQL CREATE TABLE `%vpundo` (  `who` varchar(20) NOT NULL default '',  `data` longtext NOT NULL,  PRIMARY KEY  (`who`)) TYPE=MyISAM

@SQL CREATE TABLE `%vpbbinbox` ( `id` int(11) NOT NULL default '0', `bbcode` int(11) NOT NULL default '0', `readers` longtext NOT NULL ,PRIMARY KEY (`id`,`bbcode`)) TYPE=MyISAM

THINK [ansi(h,UPLOAD COMPLETE!)][set(me,switch(1,v(quiet`before),QUIET,!QUIET))]


@@ TODO!
@@ Add mailbox limits (via config option): You cannot mail Fred, he has too many messages! 
@@ Add message size limits (via config option): You cannot write that, it would make your message too long.
@@ Finish skinning for other commands (+skim/+read/+proof. More?)